in reply to Tie::SecureHash and AUTOLOAD'ing

AUTOLOAD works fine with Tie::Securehash. Like this... 
use Tie::SecureHash;

package DogTag;

sub new 
{
        my ($class, %args) = @_;
        Tie::SecureHash->new( $class,
                                __name   => $args{name},
                                __rank   => $args{rank},
                                __serial => $args{serial}
                            );
}

sub report {
        my ($self) = @_;
        print $self->name, "\n";
        print $self->rank, "\n";
        print $self->serial, "\n";
}

sub DESTROY {}  # Usually needed when using AUTOLOAD

sub AUTOLOAD {
        my ($self) = @_;
        $AUTOLOAD =~ s/.*::/__/;
        return $self->{$AUTOLOAD};
}


package main;

my $id = DogTag->new(name=>"Smith", rank=>"private", serial=>1234567);

$id->report();

[download]

Replies are listed 'Best First'.
Re: Re: Tie::SecureHash and AUTOLOAD'ing
by forkboy (Sexton) on Apr 11, 2003 at 02:21 UTC
    arh yes, but I can also do this 
    package main;

my $id = DogTag->new(name=>"Smith",rank=>"private",serial=>'1234567');

print $id->name();

    [download]
    which somewhat defeats the purpose of Tie::SecureHash. What I really need is an autoloader that correctly enforces the same rules as Tie::SecureHash
[reply]
[d/l]
      Okay, but first notice that the AUTOLOAD is enforcing encapsulation. You can call attribute accessors, but only ever to retrieve the current values, not to set new ones.

      Remember: encapsulation is not about preventing access to attributes; it's about controlling access to attributes.

      If you want the control that the AUTOLOAD enforces to be identical to the control that Tie::SecureHash enforces (which is a perfectly reasonable thing to want), just code AUTOLOAD accordingly: 

      sub AUTOLOAD {
    my ($self, $newval) = @_;
    $AUTOLOAD =~ s/.*:://;
    my $attr;
    if (exists $self->{$attr=$AUTOLOAD}) {
        # public attribute always accessible
    }
    elsif (exists $self->{$attr="_$AUTOLOAD"}) {
        croak "Cannot access protected attribute '$attr'"
            unless caller().isa(ref $self);
    }
    elsif (exists $self->{$attr="__$AUTOLOAD"}) {
        croak "Cannot access private attribute '$attr'"
            unless caller() eq ref $self;
    }
    else {
        croak "No such attribute ($AUTOLOAD) for object"
    }
    $self->{$attr} = $newval if @_ > 1;
    return $self->{$attr};
}

      [download]
[reply]
[d/l]

In Section Seekers of Perl Wisdom