tenya has asked for the wisdom of the Perl Monks concerning the following question:

After much pain I find that the inner "for loop" preserves the outer $_ but that the inner "while loop" clobbers the outer $_. What is the general principle for the clobbering-nonclobbering of the inner $_ (you need to type something and hit return to finish the while loop). 
use strict; use diagnostics;
my @aa = ([1,2],[3,4]);
for (@aa) {
    for (1..3) {
        print $_;
        last;
    } 
print "forfor=$_\n";
}
my @bb = ([5,6],[7,8]);
for (@bb) {
    while (<STDIN>) {
        print "while=$_\n";
        last;
    } 
print "forwhile=$_\n";
}

[download]

Replies are listed 'Best First'.
Re: While but not for clobbers $_
by chromatic (Archbishop) on Apr 15, 2003 at 03:21 UTC

    You've discovered the general principle yourself -- while clobbers $_, while for implicitly localizes it. The most common suggestion is to use a lexical loop variable in your for loop:

    for my $b (@bb) {
    while (<STDIN>) {
        print "while=$_\n";
        last;
    } 
    print "forwhile=$b\n";
}

    [download]
[reply]
[d/l]
[select]
Re: While but not for clobbers $_
by BrowserUk (Patriarch) on Apr 15, 2003 at 03:33 UTC

    You can always localise $_ in your while loops yourself 

    for (1..3) {
    while(local $_=<STDIN>) {
        print; #Prints whatever was typed
    }
    print; # print 1, 2, 3
}

    [download]
    Examine what is said, not who speaks.
    1) When a distinguished but elderly scientist states that something is possible, he is almost certainly right. When he states that something is impossible, he is very probably wrong.
    2) The only way of discovering the limits of the possible is to venture a little way past them into the impossible
    3) Any sufficiently advanced technology is indistinguishable from magic.
    Arthur C. Clarke.
[reply]
[d/l]

      Although I can see the point of this to determine the scope of $_, I hope to never see code like this in production. If you want to have separate variables for nested loops, name the darn things and make the maintainer's life a little easier...

      But then again, I just spent some time today tracing a bug in one of my scripts where I did something very similar (stomp on scope when I didn't mean to, which would have been really obvious with named variables). So who knows, the sanity you save may be your own.

[reply]

        I whole heartedly agree.

        Whilst there are many conveniences that come from using $_, I doubt that there are many times when the benefits outweight the dangers of using 'it' nested like that. In this case I would definately name the variable on the for loop--BUT, I might explicitly localise $_ in the while loop also.

        The convenience of using 'it' within the body of the while loop when parsing files greatly simplifies and IM(NS)HO greatly clarifies the code.

        Explicitly localising it myself goes some way to reducing the potential for it tripping me up, and I can't see any downsides in doing so--even the extra 8 chars is too little to concern the lazy typists:)

        Examine what is said, not who speaks.
        1) When a distinguished but elderly scientist states that something is possible, he is almost certainly right. When he states that something is impossible, he is very probably wrong.
        2) The only way of discovering the limits of the possible is to venture a little way past them into the impossible
        3) Any sufficiently advanced technology is indistinguishable from magic.
        Arthur C. Clarke.
[reply]

Back to Seekers of Perl Wisdom