my %capitol_map = (
    WISCONSIN() => "Madison",
    ILLINOIS()  => "Springfield",
    ...
);
[download]

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

The tokens WISCONSON and ILLINOIS are being treated as "barewords", thanks to '=>'. To force them to be interpeted, you can do something like

  my %capitol_map = (
      (WISCONSON) => "Madison",
      ...
[download]

  my %capitol_map = (
      WI => "Madison",
      ...
[download]

The problem is your use of the stringifying comma (=>). The parser sees it following a bareword, and assumes that you want the string value "WISCONSIN" rather than the return value of the subroutine &WISCONSIN().

There are various ways around this: you can change the fat comma to a regular comma, or you can change the bareword into something Perl recognizes as subroutine call (since that's what a constant is actually implemented as).

my %capitol_map = (
    WISCONSIN , "Madison",
    ILLINOIS  , "Springfield",
    ...
);
[download]

my %capitol_map = (
    &WISCONSIN => "Madison",
    ILLINOIS()  => "Springfield",
    ...
);
[download]

Update: it has been suggested that both of these have the potential to confuse future readers of your code, which I find a strong enough argument to recommend against using this particular construct. Use the skinny comma or dws's suggestion above, instead. </update>

I was going to suggest %map = ( +WISCONSIN => "Madison"), but that doesn't actually do the trick with my perl. It does, however, work for getting keys back out of the hash, should you ever need to:

print $capitol_map{+WISCONSIN};
[download]

Nope, that's not how constants work. Actually, a constant is really a Perl sub that returns the 'constant' value. Try using another hash:

use constant WISCONSIN => "WI";
use constant ILLINOIS => "IL";

my %abbrev_map = (
   WI => 'WISCONSIN',
   IL => 'ILLINOIS',
);

my %capitol_map = (
    WISCONSIN => "Madison",
    ILLINOIS  => "Springfield",
);

my $abbrev = "WI";
if ( exists $abbrev_map{$abbrev} ) {
    print "capitol = $capitol_map{$abbrev_map{$abbrev}}\n";
}
[download]

UPDATE 2:
Well, can't seem to find one. The closest matches are:

• Geography::States (recommended)
• Geography::USStates

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

my %capitol_map = (
    +WISCONSIN => "Madison",
    +ILLINOIS  => "Springfield",
    ...
);
[download]

Makeshifts last the longest.

use constant KEY => "key";

my %h = ( +KEY => "data" , KEY() => "data",);

$, = "\n";
print "Perl vers: $]", keys %h;
[download]

Outputs:

Perl vers: 5.006001
KEY
key
[download]

Gack, you're right.

Makeshifts last the longest.

personally, i don't like the unary plus. how does it make things less ambiguous? "plus" means "not an expression"? it's not clear. besides, we have sigils to remove ambiguity, anyway. i'd recommend &WISCONSIN, or if you're afraid of side effects (which won't occur with constants,) use &WISCONSIN(). more to write, but leaving less to the imagination.

~Particle *accelerates*

I don't want to use the sigil simply because it disables the prototype and thus the constant-ish nature as mentions of the "constant" become regular runtime function calls (otherwise they'd be substituted at compile time). I might as well just use a variable.

Seeing as the unary plus doesn't work here, the next best thing I'd prefer would be (WISCONSIN) - with the parens following it looks quite awkward IMHO.

I like the unary plus in other situations and use it lots though - f.ex

map +(foo($_, "bar"))[3], @baz;
[download]

where I would otherwise be forced to use curlies

map { foo($_, "bar"))[3] } @baz;
[download]

or another extra pair of parens.

map((foo($_, "bar"))[3], @baz);
[download]

I don't like either of the latter two, though I realise quite a few people here will disagree. I think the last one at least is certain not to win any prizes for beauty..

Makeshifts last the longest.

i'd recommend &WISCONSIN, or if you're afraid of side effects (which won't occur with constants,)

Then I guess you've never noticed how "constants" are implemented by default when one uses h2xs. I've seen &CONST cause warnings in real code because of that.

But I don't use &CONST because I know it passes @_ to the CONST subroutine and I don't want whoever ends up maintaining my code wondering why I'm passing @_ in. Just because it (usually) works, doesn't mean it makes sense. (:

                - tye

use constant WI => "WISCONSIN";
use constant ILLINOIS => "IL";

my %capitol_map = (
    WISCONSIN => "Madison",
    ILLINOIS  => "Springfield",
);

my $abbrev = WI;

if ( exists $capitol_map{$abbrev} ) {
    print "capitol = $capitol_map{$abbrev}\n";
}
else { print "False" }
[download]

use constant WI => "WISCONSIN";
use constant ILLINOIS => "IL";

my %capitol_map = (
    WISCONSIN => "Madison",
    ILLINOIS  => "Springfield",
);

#THE LINE BELOW WAS CHANGED
my $abbrev = "WI";

if ( exists $capitol_map{$abbrev} ) {
    print "capitol = $capitol_map{$abbrev}\n";
}
else { print "False" }
[download]

update:Hrm.. maybe I missed the fact that the OP might have wanted the WISCONSIN in the hash to become WI not the WI in the my $abbrev to become WISCONSIN ... so my answer would then be incorrect as i seem to be answering the wrong thing.

-enlil