in reply to Re: Interchanging hash values (List::Util)
in thread Interchanging hash values

Why make two passes? 

D:\Perl\test>perl
use strict;
use warnings;

my %h; @h{'a'..'j'} = 0..9;
print %h, $/;

my ($min,$max) = (keys %h);
($min,$max) = ( $h{$min} < $h{$_} ? $min : $_, $h{$max} > $h{$_} ? $ma
+x : $_ ) for keys %h;

@h{$min,$max} = @h{$max,$min};
print %h, $/;

^Z
a0b1c2d3e4f5g6h7i8j9
a9b1c2d3e4f5g6h7i8j0

[download]
Examine what is said, not who speaks.
1) When a distinguished but elderly scientist states that something is possible, he is almost certainly right. When he states that something is impossible, he is very probably wrong.
2) The only way of discovering the limits of the possible is to venture a little way past them into the impossible
3) Any sufficiently advanced technology is indistinguishable from magic.
Arthur C. Clarke.

Replies are listed 'Best First'.
Re^3: Interchanging hash values (single pass - or not)
by Aristotle (Chancellor) on Apr 21, 2003 at 11:39 UTC
    Simply for the laziness of using List::Util. But if you're gonna optimize it, why check both conditions? An element can't be the maximum and the minimum at the same time. You're also pulling the list of all keys twice. 
    my ($min, $max) = (scalar each %h) x 2;
($min, $max) = (
    $h{$_} < $h{$min} ? ($_, $max) :
    $h{$_} > $h{$max} ? ($min, $_) :
    ($min, $max)
) for keys %h;

    [download]
    You could even go all out on each to remove the last bit of redundant work, and to reduce memory footprint. 
    my $min = each %h;
my $max = each %h;

if(defined $max) {
    local $_;
    ($min, $max) = (
        $h{$_} < $h{$min} ? ($_, $max) :
        $h{$_} > $h{$max} ? ($min, $_) :
        ($min, $max)
    ) while defined($_ = each %h);
}
else {
    $max = $min;
}

    [download]
    That's all cool if your hash is really huge. If it's just a couple pairs, I'll prefer the lazy route any day.

    Makeshifts last the longest.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom