This is what came to mind for me. You could change the line that states my %addrs = map { $_ => 1 } @addrs to my %addrs; @addrs{@addrs} = (1) x @addrs; to do a hash slice instead. I just felt like a map ;)

#!/usr/bin/perl -w
use strict;

my $addrs = do { local $/; <DATA> };
my @addrs = grep { !/domain\.com\z/ }
 $addrs =~ /"(\w+\@[\w\.]+)"/g;
my %addrs = map { $_ => 1 } @addrs;

print join("\n", keys %addrs), "\n";

__DATA__
","lliu5@yahoo.com","lliu5@yahoo.com","SMTP","support@domain.com","sup
+port@do=
main.com","SMTP"
","ishmale423@excite.com","ishmale423@excite.com","SMTP","support@doma
+in.com"=
,"support@domain.com","SMTP"
[download]

If the above content is missing any vital points or you feel that any of the information is misleading, incorrect or irrelevant, please feel free to downvote the post. At the same time, please reply to this node or /msg me to inform me as to what is wrong with the post, so that I may update the node to the best of my ability.

Cheers for that. Even better, could the addresses be piped straight to sendmail?

It would help if you showed us what you've already tried, if anything. The basic structure of the program is fairly straightforward, but the actual implementation can vary, depending upon how the input data looks and how you need output. Does your input data really begin with ","lliu5@yahoo.com","? If so, that's a strange beginning to the line. In any event, here's one structure for doing this (pseudo-code):

foreach line of input:
    split line into tokens
    foreach token in tokens
        if token is valid email and not from "domain.com"
            add token to hash
        end if
    end foreach token
end foreach line

A straight-forward implementation would go something like this (untested):

use Text::CSV_XS;
use Email::Valid;
my %email;
my $csv = Text::CSV_XS->new;

while (my $line = <DATA_FILE>) {
    chomp $line;
    if (my $status = $csv->parse($line)) {
        my @columns = $csv->fields;
        foreach my $column (@columns) {
             $email{$column} = 1 if good_email($column);
        }
    }
    else {
        warn "Could not parse ",$csv->error_input,"\n";
    }
}

sub good_email {
    my $email = shift;
    if (Email::Valid->address($email) && $email !~ /domain\.com$/i) {
        return $email;
    }
    return;
}
[download]

When that's done, your email hash keys have all unique emails. However, the list is unsorted and I my domain check is a bit dodgy, but this does give you an idea of how to proceed.

Unlike Coruscate's solution, this is fairly procedural, but it's also very easy to read.

Cheers,
Ovid

New address of my CGI Course.
Silence is Evil (feel free to copy and distribute widely - note copyright text)

cheers Coruscate that worked. I now have the e-mail addresses in a text file. what would be the best way to get a script to take each one of these addresses one by one and pass it to sendmail? i want to be able to send an e-mail to each one of the addresses in that file.

This sooo smells like what a spammer would be doing. Please give us a reason to help you.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.