# Returns:
# 1 - empty
# 0 - not empty
# -1 - doesn't exist
# Definition of "empty" -- no files/folders/links except . and ..
sub isEmpty{
   my ($dir) = @_;
   my $file;
   if (opendir my $dfh, $dir){
      while (defined($file = readdir $dfh)){
         next if $file eq '.' or $file eq '..';
         closedir $dhf;
         return 0;
      }
      closedir $dfh;
      return 1;
   }else{
      return -1;
   }
}
[download]

++ ... but ...

# -1 - doesn't exist or 
#        you don't have permission to open or read the dir
[download]

-derby

sorry, couldn't resist =]

#!/usr/bin/perl
use strict;
use warnings;

sub isEmpty {
  opendir(DIR,shift) or die $!;
  my @files = grep { !m/\A\.{1,2}\Z/} readdir(DIR);
  closedir(DIR);
  @files ? 0 : 1;
}

print isEmpty('./dir') ? "empty\n" : "not empty\n";
[download]


cp
----
"Never be afraid to try something new. Remember, amateurs built the ark. Professionals built the Titanic."

sub is_empty
{
    ! ( () = glob $_[0] . '/*' );
}
[download]

Note however that this approach employing glob will not include dot-files in the list used to determine whether the directory is empty - Thanks ++broquaint! If this is important, this code could be rewritten using the opendir, readdir and closedir sequence of commands, such as provided by perlplexer above.

Updated as per no_slogan's comments below.

perl -le 'print+unpack("N",pack("B32","00000000000000000000001001011011"))'

This won't work, because glob called in scalar context wants to iterate through all the files in a directory, and won't even look at its argument until it finishes. It will remember what directory it was reading on a previous call to is_empty. You could call glob in list context like this:

! (() = glob $_[0] . '/*');

Don't use glob in a scalar context unless you plan to drain it each time in a loop.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.