my @found;
for (0 .. $#array) {
  if ($array[$_] < 0 and $array[$_ - 1] > 0) {
    @found = @array[$_ .. $#array];
    last;
  }
}
[download]

_________
broquaint

broquaint: this appears to fail for an array such as ( -1, -2, 10, -3, 2 ), because on the first iteration (when $_ == 0 ), $_ - 1 is the last element of the array:

my @ary = qw ( a b c 2);
print $ary[-1];
[download]

Please correct (and downvote accordingly :-) if I've missed something

dave

use strict;
use warnings;

sub beaver_find
{
    my ($cond, @l) = @_;

    return () unless @l;

    my $head = shift @l;
    return $cond->( $head ) 
                ? ($head, @l)
                : beaver_find( $cond, @l );
}

my $cond = sub { my $x = shift; return $x > 0 };

my @l = ( -1, -3, -2, 10, -1, -3, -2 );

my( $head, @tail ) = beaver_find( $cond, @l );

print qq|
    Head: $head
    Tail: @tail
|;
[download]

this should do what you want. also, it will work if a zero value is found in the data, which fails with your current test. i've included some test data and examples.

#!/usr/bin/perl
use strict;
use warnings;
$|++;


sub to_zero_or_below 
{
    ## must have a two element list to process
    return unless 2 <= @_;
    for my $index ( 1..$#_ )
    {
        ## skip unless i've decended to zero or below
        next unless $_[$index - 1] > 0 and $_[$index] <= 0;
        ## return the remainder of the list
        return @_[$index..$#_];
    }
}

my @data= ( -3, -1, 1, 3, 2, 1, 0, -1, -2 );

## zero present
print $_, $/ 
    for to_zero_or_below( @data );

print "~~~\n";

## no zero
print $_, $/
    for to_zero_or_below( reverse @data );
[download]

~Particle *accelerates*

@ans = grep { ($_ > 0) .. 0 } @array;
$found = shift @ans;
[download]