Rename digital camera pictures according to date

I like my image file names to reflect the date the picture was taken. The following script renames JPEG files in the current directory according to the date stored in the EXIF headers. It also uses Term::ProgressBar to give you an idea of when it will be finished.

#!/usr/bin/perl

# Rename digital camera pictures to reflect the date they were taken
# (C) Christian Renz <crenz@web42.com> 20030615

use strict;
use warnings;
use Image::Info qw(image_info);
use Term::ProgressBar;

opendir CURDIR, '.' or
    die "Cannot open current directory: $!\n";
my @files = grep /.jpe?g$/i, readdir CURDIR;

my $progress = Term::ProgressBar->new({name  => 'Renaming images',
                                       count => scalar @files,
                                       ETA   => 'linear'});
$progress->max_update_rate(1);

foreach (@files) {
# input format:  2003:06:13 21:30:41
# output format: 2003_0613_213041
    my $date = image_info($_)->{DateTimeOriginal};
    if ($date =~ /^(\d\d\d\d):(\d\d):(\d\d) (\d\d):(\d\d):(\d\d)$/) {
        my $name = "$1_$2$3_$4$5$6.jpg";
        rename $_, $name
            unless -e $name;
    }
    $progress->update();
}
[download]

Comment on Rename digital camera pictures according to date Download Code

Replies are listed 'Best First'.
Re: Rename digital camera pictures according to date by halley (Prior) on Jun 16, 2003 at 16:24 UTC
I hand-rolled a similar script, and my wife and I both use it. However, I group photographs in directories by days, rather than changing the filename. I always keep raw camera photographs, and may also keep composites, crops or resizes in the same directory. My script does everything from mount the flashcard, copy and organize the photos, make a simple contact-sheet HTML index page, remove successfully copied items from the flashcard, and unmount. As usb-storage becomes more stable (many devices seem to have restart problems), I'll make a small daemon that watches every few seconds for mountable flashcards to make the whole process hands-free. -- `[ e d @ h a l l e y . c c ]`	[reply]

Replies are listed 'Best First'.

Re: Rename digital camera pictures according to date
by halley (Prior) on Jun 16, 2003 at 16:24 UTC

I hand-rolled a similar script, and my wife and I both use it. However, I group photographs in directories by days, rather than changing the filename. I always keep raw camera photographs, and may also keep composites, crops or resizes in the same directory.

My script does everything from mount the flashcard, copy and organize the photos, make a simple contact-sheet HTML index page, remove successfully copied items from the flashcard, and unmount. As usb-storage becomes more stable (many devices seem to have restart problems), I'll make a small daemon that watches every few seconds for mountable flashcards to make the whole process hands-free.

--
[ e d @ h a l l e y . c c ]

[reply]