in reply to Is X in my array?

It really depends. Suppose you're looking for 'a b' as a value within the array. You would get a false positive if you use this method. To correct it, I guess you can do something along these lines:

my @array = qw( a b c d x );
my $sought = 'a';
$" = '|-nothing we expect-|';
print "Found!" if index($" . "@array" . $", $" . $sought . $") > -1;

[download]

Look at that disgusting code... Please note that the preferred way to do this is grep in a scalar context:

my @array = qw( a b c d x );
my $sought = 'a';
print "Found!" if grep $_ eq $sought, @array;

[download]

With this method, you only iterate over the array instead of all the characters within the array plus $". Since grep is used in a scalar context, it returns the number of matches within the array.

Update: Ah geez.. walk away to grab a drink, come back to finish your answer and two people have posted. You guys are quick :P

antirice    
The first rule of Perl club is - use Perl
The ith rule of Perl club is - follow rule i - 1 for i > 1

Replies are listed 'Best First'.
Re: Re: Is X in my array?
by Not_a_Number (Prior) on Jun 17, 2003 at 19:00 UTC

    Thanks, antirice. But I always thought it wasn't good practice to use grep for such purposes. From perlfaq4, How can I tell whether a certain element is contained in a list or array?:

    Please do not use ($is_there) = grep $_ eq $whatever, @array;

    Am I missing something?

    Thanks again

    dave
[reply]
[d/l]
[select]

      If you are searching through the array multiple times, then right, this isn't the best option. If you are reusing the array to compare against, the best practice is this:

      my @array = qw ( a b c d x );
my %hashcheck;
@hashcheck{@array} = ();

my $sought = 'a';
print "Found!" if exists $hashcheck{$sought};

      [download]

      The reason they suggest not using grep is because it is a O(n) algorithm whereas checking for exists is O(1). When you continuously check @array to see whether or not items can be found, it would be much slower to use grep.

      As for their suggestion in the case that the array is checked only once, I could go either way. Their method is actually 17% faster on a million iterations (my benchmarks, YMMV), but I find grep easier to read.

      antirice    
      The first rule of Perl club is - use Perl
      The       ith rule of Perl club is - follow rule i - 1 for i > 1

[reply]
[d/l]

In Section Seekers of Perl Wisdom