my @array = qw/ foo bar baz foo quux baz /;

print map "$_\n", keys %{ {map {$_ => 1} @array} };

__output__

foo
quux
baz
bar
[download]

_________
broquaint

Thank you, it now works. If possible can you please explain what is going on in this statement?

print map "$_\n", keys %{ {map {$_ => 1} @array} };
[download]

I am lost on the keys and map part??

Alrighty, let's break it down then

map { $_ => 1 } @array
[download]

For each value in @array apply the transform in the block (denoted by the curly braces), in this case create a two element list consisting of each element of the list and a literal 1, collect the output of those transforms and return them as a list. So the map creates a list of key-value pairs (although the value is superfluous in this case) perfect for a hash ...

{ map { $_ => 1 } @array }
[download]

The extra curly braces around the map statement create an anonymous hash, so all duplicate keys in the list created by map are collapsed in the anonymous hash.

keys %{ {map {$_ => 1} @array} }
[download]

Dereference the anonymous hash created and return a list of its keys.

print map "$_\n", keys %{ {map {$_ => 1} @array} };
[download]

The final map then simply a creates a list where each key has a \n appended and then print prints that list.
HTH

_________
broquaint

Abigail

foreach (@values) {
    print "$_\n" unless $seen{$_}++;
}
[download]

The %seen hash keeps track of which elements you've seen before, and only prints ones which haven't been seen.

#!/usr/bin/perl -w
use strict;

my @array = ( 2, 4, 5, 5, 7, 8, 21, 22, 22, 30 );
my %count;

foreach ( @array ) {
  $count{$_}++;
}

foreach ( @array ) {
  print "$_ " if $count{$_} < 2;
}

Output:

2 4 7 8 21 30
[download]

You can print unique values in array order using a variation on the standard hash trick:

my %unique;
@unique{@values} = ();

for (@values) {
    next unless exists $unique{$_};
    print $_, $/;
    delete $unique{$_};
}
[download]

Update: A simpler way that leaves you with the %unique hash populated:

my %unique;
for (@values) {
    next if exists $unique{$_};
    print $_, $/;
    $unique{$_}++;
}
[download]

After Compline,
Zaxo

If you want to preserve the order of the first seen item

@values = qw(this is a test of the hello test of the test artist hello
+ world);
@unqiue_values =   grep { !$seen{$_}++   } @values;
print join " " => @unqiue_values,"\n";
__END__
this is a test of the hello artist world
[download]

artist