First things first... %hash->{"IP"} ... don't use that syntax. It's deprecated. It isn't widely used. It is easily confused with a dereference. Did I mention that it's deprecated? It was only by accident that it worked in the first place. It's long and ugly. Oh, and it is deprecated too. Don't use it. Use $hash{IP} instead. You'll be doing yourself a favor.

Ok, now that that is out of the way, let's rewrite your code a bit. We'll clean up the indenting, combine the declarations and initializations, and remove a little cruft. Let's get rid of your @rows array too; it isn't necessary for this example (all you use it for is to hold the value 'IP'.) We can also get rid of your loop at the end because the example only deals with one key: IP.

my @newrows = qw( value1 value2 );
my @printrows;
my %newhash;

push @{$newhash{ IP }}, @newrows;
push @{$newhash{ IP }}, @newrows;

@printrows = $newhash{ IP };
print $printrows[0][0], "\n"; # should be Value1?
print $printrows[1][1], "\n"; # should be Value2?
print "\n";
[download]

There. Now your question becomes a little more clear. It seems you are a little confused about how complex data structures work.

Step by step...

push @{$newhash{ IP }}, @newrows;
[download]

After that line is evaluated, $newhash{ IP } holds a reference to an array. The elements of the array are copies of the same two elements that are in @newrows, namely 'value1' and 'value2'.

After you do it again with

push @{$newhash{ IP }}, @newrows;
[download]

the array that your reference, $newhash{ IP }, refers to contains 2 copies of the @newrows array. It might be easier to see what you are doing if you remove some complexity. Examine the one-liner perl -le 'my @a = (1, 2); push @b, @a; push @b, @a; print for @b' and its output.

So, that's the mistake you made during construction of your data structure. Now let's take a closer look at how you attempt to use it.

@printrows = $newhash{ IP };
[download]

That doesn't do what you expect it to. After that, @printrows has one element: the reference stored in $newhash{ IP }. If you want to copy the array refered to by that reference, then you'd need something like @printrows = @{ $newhash{ IP } }; instead.

Moving on...

print $printrows[0][0], "\n"; # should be Value1?
[download]

Indeed, that is 'value1'. Just not for the reasons that you'd like it to be. That only works because of the error you made in the last step. Remember that @printrows holds a single value, a reference. That reference, $printrows[0] is a reference to the array you constructed. The first element in that array, $printrows[0]->[0] which can also be written in short form as $printrows[0][0], is 'value1'.

The next line

print $printrows[1][1], "\n"; # should be Value2?
[download]

fails to print 'value2'. Once again, recall that @printrows only has one element. That element is indexed by 0 (where we found it above.) There is no element at index 1, so $printrows[1] evaluates to undef. So does $printrows[1][1] for that matter. However, had you been running with warnings enabled (either with the -w switch to perl or the use warnings pragma), you would have found that this line resulted in the message "use of uninitialized value in print at ..." which might have helped some.

You should probably read some of the tutorials that come with perl like perlreftut, perldsc, perllol. For reference, you should also familiarize yourself with perldata.

Good luck!

-sauoq
"My two cents aren't worth a dime.";