Two words (three?): use Time::Piece!

use strict;
use warnings;
use Time::Piece;

my $t = localtime;
my @d = $t->day_list;
printf "%s, %s %d, %d\n\n\n",
   $d[($_ + 1) % 7],
   $t->fullmonth, 
   $_, 
   $t->year
   for 1..$t->month_last_day
;
[download]

Whoopsie Daisy! This only works for this month and this year ... see the modulus up there? That was suppose to be ($_ - 1) % 7 and i accidentally added one instead. That, of course, doesn't work, but my blunder managed to give "correct looking" results. Here is a better version whose output is identical to yours (the days of the names are not abbreviated):

use Time::Piece;

my $t = localtime;
my $last = $t->month_last_day;
$t -= Time::Piece::ONE_DAY * ($t->mday - 1);

for (1..$last) {
   printf "%s, %s %d, %d\n\n\n",
      $t->fullday,
      $t->fullmonth,
      $t->mday,
      $t->year
   ;
   $t += Time::Piece::ONE_DAY;
}
[download]

[This still] doesn't save to a file, but redirection works just as well, IMHO. Hope this helps. :)

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)