The obvious answer would be to add a method reset_count() in the block, but you would have to explicitly call it before sorting, which is prone to errors.

Another way is to put together a state and a behaviour, building an object.

use strict;

my @list1 = qw/ box cow dog apple ant/;
my @list2 = qw/ ant apple box cow dog/;

sub make_a_profilable_sorter
{
    my $criterion = shift;
    
    return sub {
        my $counter = 0;

        my @list = @_;

        @list = sort { $counter++; $criterion->( $a, $b ) } @list; 

        return ( $counter, @list );
    }
}

my $sorter1 = make_a_profilable_sorter( sub{ $_[0] cmp $_[1] } );
my $sorter2 = make_a_profilable_sorter( sub{ $_[0] cmp $_[1] } );

my ($count, @res) = $sorter1->( @list1 );
print "I sorted /@list1/ in $count steps producing /@res/\n";

my ($count, @res) = $sorter2->( @list2 );
print "I sorted /@list2/ in $count steps producing /@res/\n";
[download]

• Frames as repository of local state in Structure and Interpretation of Computer Programs
• On Lisp by Paul Graham. Start at page 30 (in the free pdf file)

Thank you. In case it is not obvious I am trying to learn to do functional programming in perl. I have done it in lisp, but am trying to move my understanding to perl. Your code is where I thought I was going in the first place. My mistake was trying to put the sort outside the closure.

--traveler

That's becauase this is a closure and $count retains its value between calls, since there is actually an instance of $count being carried around in the coderef.

Either move $count into the outer scope, so you can clear it between calls, or generate a new set closures, modding the previous poster's code Re: Closures and sort :

use strict;

my @list = qw/ box cow dog apple ant/;

sub mksub
{
    my $count = 0;

    my $s1 = sub  { return $count }; # an inspector as a closure

    # and another closure
    my $s2 = sub
    {
        $count++;
        return $_[0] cmp $_[1];
    };

    return ( $s1, $s2 );
}

my ( $get_count, $compare, );
( $get_count, $compare, ) =  mksub();
print sort { $compare->( $a, $b ) } @list;
print "\n";
print $get_count->(), "\n";
print "\n";

print sort { $compare->( $a, $b ) } @list;
print "\n";
print $get_count->(), "\n";
print "\n";

( $get_count, $compare, ) =  mksub();
print sort { $compare->( $a, $b ) } @list;
print "\n";
print $get_count->(), "\n";
print "\n";
[download]

antappleboxcowdog
9

antappleboxcowdog
18

antappleboxcowdog
9

Phooey. Bit by the nested subs "feature". Thank you.