Not to be a stick in the mud, but please remember that not all credit cards are 16 digits long. For instance, AMEX is 15 digits (4-6-5 or s/(.{4})(.{6})(.{5})/$1 $2 $3/) and some VISA cards are 13 digits (4-3-3-3 or s/(.{4})(.{3})(.{3})(.{3})/$1 $2 $3 $4/).

On a side note, you can use Business::CreditCard to tell what type of credit card you are dealing with as well as whether or not the credit card's checksum is valid.

Hope this helps.

antirice    
The first rule of Perl club is - use Perl
The ith rule of Perl club is - follow rule i - 1 for i > 1

If you end up with a simple function that normalizes the punctuation of various credit cards based on type, I'd suggest submitting it as a contribution to Business::CreditCard. It'd be a nice contribution and an obvious place for people to look for it in the future.

sub format_cc_num
{
    my ($num, $spacer) = @_;

    $num = reverse $num;
    $num =~ s/(.{4})/${1}${spacer}/g;
    return reverse $num;
}
[download]

------
We are the carpenters and bricklayers of the Information Age.

The idea is a little like C++ templates, except not quite so brain-meltingly complicated. -- TheDamian, Exegesis 6

Please remember that I'm crufty and crochety. All opinions are purely mine and all code is untested, unless otherwise specified.

Careful. Context will trip you up when playing with reverse. ++ otherwise.

return scalar reverse $num;
[download]

Why does everyone reach for substitution though?

sub format_cc_num {
    my ($num, $spacer) = @_;
    scalar reverse join $spacer, (reverse $num) =~ /(....)/g;
}
[download]

Makeshifts last the longest.

Actually, we both were buggy. Using your code and my code (with the appropriate bugfix), we have:

#!/usr/bin/perl
 
use strict;
use warnings;
 
my $x = "12345678";
my $y = "123456789";
 
sub dragonchild
{
   my ($n, $s) = @_;
 
   $n = reverse $n;
   # Added negative lookahead
   $n =~ s/(.{4})(?!$)/${1}${s}/g;
   scalar reverse $n;
}
 
sub aristotle
{
   my ($n, $s) = @_;
   scalar reverse join $s, (reverse $n) =~ /(....)/g;
}
 
foreach my $v ($x, $y)
{
   print dragonchild($v, '-'), $/;
   print aristotle($v, '-'), $/;
}

------

1234-5678
1234-5678
1-2345-6789
2345-6789
[download]

Your code only works for card numbers that are a multiple of 4. Most department store cards are 11 digits and some, like AmEx, are moving to 17 or 19 digits. (I used to work for MC ... we had a similar function that I had to maintain in the app I worked on. It was written horribly with substr and the like.)

------
We are the carpenters and bricklayers of the Information Age.

The idea is a little like C++ templates, except not quite so brain-meltingly complicated. -- TheDamian, Exegesis 6

Please remember that I'm crufty and crochety. All opinions are purely mine and all code is untested, unless otherwise specified.

#!/usr/bin/perl -w
use strict;
my $number = '4744760012394122';

if ($number =~ /^(\d{4})(\d{4})(\d{4})(\d{4})$/) {
    $number = "$1 $2 $3 $4";
}
else {
    print "Unable to convert $number\n";
}
[download]

Cheers - L~R

I would use:

$number =~ s#(.{4})#$1 #g;
[download]

There should be a quick way doing this with unpack(), but the heat just got to me... ;-)

Liz

Update
Hmmm... that puts a space at the end. which may or may not be a problem. And it doesn't check for digits. So I guess this would be better:

$number =~ s#(\d{4})(?=\d)#$1 #g;
[download]

or:

$number = "@{[unpack '(A4)*', $number]}";
[download]

but that is heading towards obfuscation ;-) (thanks tedrek!)

print join " ", unpack("A4A4A4A4", $number)

TIMTOWTDI.

print join ' ', '4744760012394122' =~ m[(....)]g
4744 7600 1239 4122
[download]

Check it out:

#!/usr/bin/perl -w
###################################
 
use strict;
use warnings;
use diagnostics;
 
my $cc="4744760012394122";
 
$cc =~ s/(\d{4})(\d{4})(\d{4})(\d{4})/$1 $2 $3 $4/;
 
print $cc,"\n";
[download]

My attempt.

my $cc_num; # Intitilized elsewhere
print join ' ', unpack('A4 A4 A4 A4', $cc_num);
[download]

----
I wanted to explore how Perl's closures can be manipulated, and ended up creating an object system by accident.
-- Schemer

Note: All code is untested, unless otherwise stated

And let's throw a substr solution into the mix as well :)

$n = "4744760012394122";
$r = substr($n,-4,4,"")." ".$r while $n ne "";
[download]