Well, there are a couple ways to do it. Here are three:

• System calls to `ls' and `grep' (like you did).
• Perl's internal system calls to list files and grep the lists.
• Use File::Find at the top of a directory tree and look for *.mp3.

Out of these three, I would definitely recommend File::Find. There is the least chance of something going horribly, horribly wrong. :-) You should read the File::Find manpage, but since you are a self-proclaimed newbie, I'll give you an example!

#!/usr/bin/perl

# enable strict syntax checking and warnings
# you should (pretty much) always use these
use strict;
use warnings 'all';

# include our friendly neighborhood file finder
use File::Find;

sub list_mp3 {
    # our regex to check for the .mp3 extension
    /.*?\.mp3$/ && do {
 
    # but we're not done yet!
    # this `do' block will perform any voodoo and output
    # you want on files that match the above regex

    # here's a real simple output:
    print $File::Find::name, "\n";

    # See the File::Find manpage for the different variables to use.
    # You can obviously dress the output up a lot more than this.

    } # end the do-block
} # end the subroutine

# finddepth() is a function from File::Find
# we have to tell it A) what function to use, and
#                    B) where to start searching
#
# this will start at /hd/mp3 and search downward, passing
# each file to the list_mp3 function above

finddepth(\&list_mp3, '/HD/MP3');
[download]

If you need me to clarify anything, just holler. Hopefully this will be enough to get you started!

Alakaboo

#!/usr/bin/perl -w
use File::Find;

finddepth(\&output, '.');

sub output {
    return if $File::Find::name !~ /.mp3$/;
    print "<p>$File::Find::dir</p>\n";
    (my $n = $File::Find::name) =~ s/.*\///;
    print "\t<blockquote>$n</blockquote>\n";
}
[download]

#!/usr/bin/perl -w
use File::Find;
use vars qw($prev);
finddepth(\&output, '.');

sub output {
    return if $File::Find::name !~ /.mp3$/;
    print "<p>$File::Find::dir</p>\n" if $File::Find::dir ne $prev;
    $prev = $File::Find::dir;
    (my $n = $File::Find::name) =~ s/.*\///;
    print "\t<blockquote>$n</blockquote>\n";
}
[download]

Unfortunately that outputs a directory at the top of MP3 name. How can I remove that?

Cheers,
KM

per jeffa's suggestion, this node has a disclaimer.

THIS NODE CONTAINS NO PERL CODE AND SUGGESTS A SOLUTION OTHER THAN PERL.
it appears that `sort` below can be broken with embedded newlines.(thanks, tilly) shame on you for using embedded newlines in your mp3 names. :)
and now, for something completely different...

Other people have commented on File::Find, which is useful and 100% perl. However, I have also run into this problem and found it to be more shell-esque than perl-esque (at least in my situation, ymmv).

I use the following shell script, which requires slocate. The good news is it has regex abilities. Soooooo, I wrote this small script which is very useful:

#!/bin/bash
slocate -U /home/mp3 -o /home/mp3/mp3s.sldb ;
rm -f /home/mp3/playlist_* ;
rm -f /home/httpd/html/playlist/playlist_* ;
slocate -d /home/mp3/mp3s.sldb -r '\.[Mm][Pp]3$' | sort >  "/home/mp3/
+playlist_`date | cut -c1-3`_`date | awk '{print $4}' | cut -d: -f1,2`
+" ;
chown alex.wheel /home/mp3/playlist_* ;
cp /home/mp3/playlist_* /home/httpd/html/playlist ; 
chown alex.wheel /home/mp3/mp3s.sldb  ;
[download]

--
#!/bin/dep

use strict;
use File::Find;
use File::Basename;

my($topdir) = '/'; # where you want to start from

my(@files) = find ( \&wanted, "$topdir" );

foreach (@files) {
    my($dir) = dirname($_);
    if ($dir ne $prev_dir) {
        print "<P>" . $dir . "</P>\n";
        $prev_dir = $dir;
    }
    print "<BLOCKQUOTE>" . $_ . "</BLOCKQUOTE>\n";
} 

sub wanted {
    /\.mp3$/ && -f;
}
[download]

Your reply is the easiest for me to understand, but there seems to be an error in the regexp. I get this response.

Thu Aug 17 21:41:17 2000 index.cgi: /*.mp3$/: ?+*{} follows nothing in regexp at ./index.cgi line 34.

So what happenened?? I am no good at regexps, and I've never used them out of m// or s///. I have copied your code exactly three times, I tried to make sense of it, but it has me stumped (surprise, surprise, surprise).

The regular expression is simply wrong :-). A regular expression that matches everything with the extension .mp3 would be for example :

  /\.mp3$/
[download]

A quick explanation : The \.mp3 part is to ask for a literal dot followed by mp3 and the $ part is that the string must end after this. This is also the shortest regular expression that will match all files with an extension of .mp3.

Another regular expression, more in the spirit of the faulty RE would have been

  /.*\.mp3$/
[download]

in which you'll recognize the \.mp3$ part from above plus the .* part, which means "match an arbitrary character" (the dot) "zero or more times" (the star).

As a Perl newbie, getting familiar with regular expressions is quite a task, but you can never start too early with them - in fact, I like Perl as it is the only language I know with REs built into the language core :-)

Some recommended reading on regular expressions is the RE man page and of course the book "Mastering Regular Expressions" by Jeffrey Friedel - but that one contains more about REs than you ever thought there is to know.