This code should do what you need:

open(F, '<', './files.txt') or die "open: $!";
while ($filename = <F>) {
  chomp($filename);
  $dot = rindex($filename, '.');
  if ($dot > -1) {
    $extension = substr($filename, $dot+1);
    $extensions{$extension}++;
  } else {
    $extensions{'_without_extension'}++;
  }
}
close(F);

while (($key, $value) =  each %extensions) {
  print "$key -> $value\n";
}
[download]

Ciao, Valerio

update: thanks liz!

One small nit. I would replace this code:

if ($dot > -1) {
    $extension = substr($filename, $dot+1);
    $extensions{$extension}++;
} else {
    $extensions{'_without_extension'}++;
}
[download]

by:

$extensions{$dot == -1 ? '' : substr( $filename,$dot )}++;
[download]

for two reasons:
1. it's more compact
2. it allows you to differentiate between filenames without extension (no . found) and with an empty extension (a . at the end).
Liz

Depending on how much of the work you really need to do yourself, File::Basename is a option.

use File::Basename;
use strict;

my %exts;

open FILE , '/some/big/file' or die "Screaming $!";
while ( <FILE> ) {
 chomp;
 my $file = $_;
 my ($name, $path, $suffix) = fileparse( $file , '\..*' );
 $exts{$suffix}++;
}

# Dump your hash here.
[download]

Update: Totally untested , looks OK to me.

my %ext;
while (<>) {
   next unless /\S/;
   /(\.[^.]+)?$/;
   $ext{lc($1||"")}++;
}
printf "%-6s %d\n",$_||'<NONE>',$ext{$_} for sort keys %ext;
[download]

Remove the lc() if you are on a case sensitive file system.