in reply to To || or not to or and why.

Abigail-II and dws have valid points you should take to heart, but don't answer your original question which is about the difference between or and ||. The difference is in precedence, || has higher precedence than or. This can be found in the perlop manpage.

Note: especially keep in mind the relative precende of or and || with respect to assignment.

Just my 2 cents, -gjb-

Replies are listed 'Best First'.
Re^2: To || or not to or and why.
by flounder99 (Friar) on Sep 16, 2003 at 12:08 UTC
    A good example of the difference in precedence of or and || is in the common perl idiom of 
    open FILE, "file" or die;

    [download]
    it is not the same as 
    open FILE, "file" || die;

    [download]
    since || has a higher precedence than open the "file" || die gets evaluated before the open. So it will not die even if the open fails. or has a lower precedence than open so the open gets evaluated first in the first example. To have the same effect using || you have to use 
    open(FILE, "file") || die;

    [download]

    --

    flounder

[reply]
[d/l]
[select]

      Flounder,

      Thank you for that explaination. So if I am reading it right, then the would following be true?
       
      The following functions set the value of the return to 'default' by default. Then if was a parameter passed, $value gets set to that parameter. The differences between the two are:
      1. The juxteposition of the shift() statement and 'default'
      2. The use of the '||' and 'or' operators
      sub setValue_takeOne{
  my $value = shift() || 'default';
  return $value;
}

sub setValue_takeTwo{
  my $value = 'default' or shift();
  return $value;
}

      [download]

[reply]
[d/l]
        No. 
        my $value = shift() || 'default';

        [download]
        and 
        my $value = shift() or 'default';

        [download]
        will not work the same. 
        my $value = shift() || 'default';

        [download]
        will set $value to the value returned by shift() if it is true and to 'default' if it is false. 
        my $value = shift() or 'default';

        [download]
        will set $value to the value returned by shift() no matter what!
        Here is an example using a handy tool B::Deparse that will show you how the compiler read your program, the -p adds extra parentheses to make it very clear. 
        #temp.pl
$value = $x or $y or $z;
$value = $x || $y || $z;
$value = $x or $y || $z;
$value = $x || $y or $z;

        [download]
        then run 
        perl -MO=Deparse,-p  temp.pl

        [download]
        it outputs 
        ((($value = $x) or $y) or $z);
($value = (($x || $y) || $z));
(($value = $x) or ($y or $z));
(($value = ($x || $y)) or $z);
temp.pl syntax OK

        [download]
        if you notice 
        $value = $x or $y or $z;

        [download]
        and 
        $value = $x or $y || $z;

        [download]
        just set $value to the value of $x no matter what the value of $y or $z because or has a lower precidence than =.
        Did you notice that 
         
$value = $x || $y or $z;

        [download]
        will just set $value to the value of $x || $y no matter what the value of $z?

        --

        flounder

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom