Try this

perl -pe"s[ (?<=\\|/) (.*?) (?=\\|/) ][ (my$x=$1) =~ s{ }{_}g; $x]gex"
+ file
[download]

Thanks!
I would appreciate if you could tell me how to implement the same in a program? I would start with open FH, "<file";

I would start with open FH, "<file";

No, you should not. You should always test the return value of open. Furthermore, I wouldn't use second class variables if I can avoid it. Finally, you may prefer 3-arg open over magic 2-arg open:

    open my $fh, "<", "file" or die "Failed to open 'file': $!";
[download]

Abigail

Something like this (untested) code may be what your looking for.

#! perl -w
use strict;

open IN, '<', 'file' or die $!;
open OUT, '>', 'temp' or die $!;

while( <IN> ) {
    s[ (?<=\\|/) (.*?) (?=\\|/) ][ 
        (my$x=$1) =~ s{ }{_}g; 
        $x
    ]gex;
    print OUT;
}

close IN;
close OUT;
rename 'file', 'file.bak';
rename 'temp', 'file';
[download]

You could also look at using $INPLACE_EDIT ($^I) to have perl do the backup and rename for you.

---

Examine what is said, not who speaks.
"Efficiency is intelligent laziness." -David Dunham
"When I'm working on a problem, I never think about beauty. I think only how to solve the problem. But when I have finished, if the solution is not beautiful, I know it is wrong." -Richard Buckminster Fuller
If I understand your problem, I can solve it! Of course, the same can be said for you.

I believe this code will work. I assume that the filename is the last thing on the line so I split on the :/ after the drive letter (notice it handles both types of slashes) and then it substitutes spaces anywhere after that in the string:

#!/usr/bin/perl -w
use strict;
                                                                      
+          
while(<DATA>)
{
my @line=split /(:[\\\/])/;
$line[2]=~s/ /_/g;
print join "", @line;
}
__DATA__
124334 2323 c:\program files\somefile
124334 2323 c:\program files\somepath\somefile
124334 2323 c:\program files\with space/somefile
124334 2323 c:\program files\with space/with another space/somefile
[download]

HTH

Just for the fun of it, here's an approach using lvalues:

  substr($line, 12) =~ s/ /_/g;
[download]

Hope this helps, -gjb-

If you're passing this data to another application that will choke on the spaces, you may want to check and see if quoting the directory/file names will work. Then you could do something like....

perl -i.bak -lne '@F=split(/ /,$_,3);print "$F[0] $F[1] \"$F[2]\""' filename

Of course, that doesn't take into account any lines not matching the expected format (e.g., blank lines are no longer blank)