my @values = qw(Stuff you want to pass in);
print "Some question\n";
chomp(my $file = <>);
if ($file eq 'A') {
    do_A($file, @values);
} elsif ($file eq 'B') {
    do_B($file, @values);
} elsif ... {
} else {
    complain_that_value_sucks($file, @values);
}
[download]

Now, that's a really piss-poor thing, especially if you have more than 5-10 options. So, we can use a dispatch table. This is a preferred method of doing things.

my %dispatch_table = (
    A => \&do_A,
    B => \&do_B,
    C => \&do_C,
);

my @values = qw(Stuff you want to pass in);

print "Some question\n";
chomp(my $file = <>);

my $sub = $dispatch_table{$file} || \&complain_that_value_sucks;
$sub->($file, @values);
[download]

Now, the dispatch table can be in a module, built on-the-fly, or whatever. What's happening here is that we're taking references to subroutines and associating them with strings. So, whenever we see a given string, we can map that to the given subroutine. This is very similar (but more powerful) to funcp's in C/C++.

------
We are the carpenters and bricklayers of the Information Age.

The idea is a little like C++ templates, except not quite so brain-meltingly complicated. -- TheDamian, Exegesis 6

Please remember that I'm crufty and crochety. All opinions are purely mine and all code is untested, unless otherwise specified.

I would provide examples, but can't possibly do so as effectively as the POD that comes with the module. See the perldocs for Getopt::Std for more info. It really is pretty simple to use and is much more robust than any "roll your own" technique could be (assuming again, that you, like I, are 'still pretty new').

Dave

"If I had my life to do over again, I'd be a plumber." -- Albert Einstein

#!/usr/bin/perl
use Getopt::Long;
use Pod::Usage;  # Recomend to use Pod::Usage along with Getopt::Long
use strict;

# Parse command line arguments and assign corresponding variables
GetOptions
(
    'f|fruit=s'  => \( my $fruit  = undef ),
    'a|action=s' => \( my $action = undef ),
    'g|greet'    => \( my $greet  = undef ),
);

unless ( defined $action && defined $fruit )
{
    pod2usage( -exitval => 1, -output => \*STDERR );
}

# do greeting
print "Hello there!\n" if ($greet);

# multiple fruit possible
my @fruit = split /,/, $fruit;

foreach (@fruit)
{
    print "I will $action $_.\n";
    # etc...
}

exit(0);

__END__

=pod

=head1 NAME

fruit.pl

=head1 SYNOPSIS

fruit.pl [options]

=head1 ARGUMENTS

The -f and -a options are mandatory. The -g option is optional.

=over 4

=item B<-f|--fruit [name]>

Specify the fruit, multiple fruits possible, separate by comma

=item B<-a|--action [name]>

Specify the action to perform on fruit.

=item B<-g|--greet>

Print the greeting.

=back

=cut
[download]

perl ./fruit.pl -f apple,orange -a eat -g
perl ./fruit.pl --fruit banana -action sell
...
[download]