I was always taught that the correct way of printing lists like that was "A, B, C and D" (i.e. no comma before the "and"). If your English teacher was like mine then this version will work better for you:

sub and_a_list {
  if (@_ > 2) {
    join(", ", @_[0..$#_-1]) . " and $_[-1]"
  } elsif (@_ > 1) {
    "$_[0] and $_[1]"
  } elsif (@_ > 0) {
    $_[0]
  } else {
    ""
  }
}
[download]

That particular lie was propogated by newspaper publishers who thought they could save millions by dropping all those "extra" commas. Leaving the last commas off makes for a lot more ambiguity. Unfortunately, many academics got convinced that if newspapers write that way it must be a good idea.

My favorite breakfasts are bacon and eggs, blueberry muffins, and sausage and biscuits. Take one, two or three times daily.

        - tye (but my friends call me "Tye")

Thanks for that little bit of brain lint.
I always "corrected" myself. I wondered why it never looked
right to me.

If you don't want that comma, you can do without the cases:

sub list {
    join ", " => @_ [0 .. $#_ - 2],
                 join " and " => @_ [grep {$_ >= 0} $#_ - 1, $#_]
}
[download]

Abigail

sub list {
    join(" and ", reverse grep defined && length, pop @_, join(", ", @
+_))
}
[download]

Makeshifts last the longest.

sub and_a_list {
    my $r = join(', ', @_);
    my $pos = rindex($r, ', ');
    substr($r, $pos, 2) = ' and ' if $pos > -1;
    $r;
}
[download]

My version. What can I say, I like the ? : operator :)

Usage: &print_with_ands(\@array);

sub print_with_ands {
  my $x=0;
  my $a=shift;
  printf "$a->[$x-1]%s",
    defined $a->[$x+1] ? ", " : 
    ! defined $a->[$x] ? "\n" : 
    $x==1 ? " and " : ", and " 
    while defined $a->[$x++];
}
[download]

sub serial(@) {
    join(', ', @_[0..$#_-1]) . 
        (@_>2 ? ',':'' ) . 
            (@_>1 ? (' and ' . $_[-1]) : $_[-1]);
}
[download]

Hey! You can't see the join's :)

#! perl -sw
use strict;
sub npAndAList{$"=', '; return unless @_; @_==1 and "@_" or "@_[0 .. $
+#_-1] and $_[-1]" }
print npAndAList(qw(a b c d e)[0..$_]),$/ for -1..4;
__DATA__
a
a and b
a, b and c
a, b, c and d
a, b, c, d and e
[download]

---

Cor! Like yer ring! ... HALO dammit! ... 'Ave it yer way! Hal-lo, Mister la-de-da. ... Like yer ring!

What about this?

sub andify {
  return '' unless @_;
  return $_[0] if @_ == 1;
  local $" = @_ == 2 ? ' ' : ', ';
  $_[-1] = 'and ' . $_[-1];
  return "@_";
}
[download]

20050525 Edit by ysth: p, code tags