key1            key2            key3            key4            key5
$data{key1}[0]  $data{key2}[0]  $data{key3}[0]  $data{key4}[0]  $data{
+key5}[0]
$data{key1}[1]  $data{key2}[1]  $data{key3}[1]  $data{key4}[1]  $data{
+key5}[1]
$data{key1}[2]  $data{key2}[2]  $data{key3}[2]  $data{key4}[2]  $data{
+key5}[2]
...
[download]

my $col_width = 20;
my @keys      = sort keys %data;
my $p_format  = join(" " => ("%${col_width}s") x @keys) . "\n";

## $p_format would be "%20s %20s %20s ... %20s\n", so the columns will
## line up even if the data strings are different sizes

printf $p_format, @keys;

my $i = 0;
LOOP: {
    ## important part: pull out the ith entry in each array
    my @ith_data = map { $data{$_}[$i] || "" } @keys;

    ## you mentioned the data strings end in \n
    chomp @ith_data; 

    printf $p_format, @ith_data;

    $i++;

    ## loop again if any array has elements left
    for (@keys) {
        redo LOOP if exists $data{$_}[$i];
    }
}
[download]

I used printf to print things out in aligned columns, but if your data strings are all the same length, you could just as easily use print "@ith_data\n"... although that would start looking weird if some arrays run out of elements early. But if your arrays are all the same size, and your data strings are all the same length, you could get this code down to:

my @keys = sort keys %data;
for my $i ( 0 .. $size-1 ) {
    my @ith_data = map { $data{$_}[$i] || "" } @keys;
    chomp @ith_data; 
    print "@ith_data\n";
}
[download]

blokhead,
You may want to modify your map line:

my @ith_data = map { defined $data{$_}[$i] ? $data{$_}[$i] : '' } @key
+s;
[download]

This way 0 and "0" will not get changed to "".

Cheers - L~R

This is exactly what I am looking for!! It is a very different way of doing things compared to the direction I was heading, but works very nicely. Always glad to learn new stuff....Thanks!!!

Bioinformatics

#!/usr/bin/perl -w
use strict;
use Text::CSV;

my %data = (
    one   => [ qw(a b c d e f g h i j k) ],
    two   => [ qw(1 2 3 4 5 6 7 8) ],
    three => [ qw(john jacob jingle heimer smitz) ]
);

my @keys = sort keys %data;
my $max = 0;

for ( @keys ) {
    $max = @{$data{$_}} if @{$data{$_}} > $max;  
}

Excel(\@keys);

for my $index ( 0 .. $max ) {
    my @temp;
    for my $key ( @keys ) {
        push @temp, defined $data{$key}->[$index] ? $data{$key}->[$ind
+ex] : '';     
    }
    Excel(\@temp);
}

sub Excel {
    my $array = shift;
    my $csv = Text::CSV->new;
    if ( $csv->combine(@{$array}) ) {
        my $string = $csv->string;
        print $string, "\n";
    }
    else {
        my $err = $csv->error_input;
        print "combine() failed on argument: ", $err, "\n";
    }
}
[download]

Update: Added Text::CSV stuff since it sounded like the output is going to Excel.

Does it need to be readable by an end user, or is it just for debugging something? If debugging, use Data::Dumper.

I've heard a lot about Data::Dumper, but haven't used it much. The data is to be read in excel format, so using Data::Dumper won't help in this situation. Thanks for the suggestion though!!

Bioinformatics

Where does the 4 columns bit come from?

If each value is "\n" terminated, I would expect to see a single, very long column output from you code

Unless each individual element of each array actually contains 4 space or comma delimited fields terminated by a newline?

A little (abbreviated) sample datam plus a C&P from the resultant file and an example of how you would like that same output formatted would go a long way to clarifying your question.