It is not a problem when run as is, because it does not really create a closure when the lexical is declared at the top level outside of any subroutine (I may be wrong, but it's at least a closure that doesn't create any problems...yet). So this works ok:

use strict;      
use warnings;    
                 
my $foo = 'foo'; 
bar();           
                 
$foo = 'bar';    
bar();           
                 
sub bar {        
  print "$foo\n";
}
[download]

The problem comes when the script is run under Apache::Registry, because it turns the script into something like this:

sub foo1234 {    
                 
use strict;      
use warnings;    
                 
my $foo = 'foo'; 
bar();           
                 
$foo = 'bar';    
bar();           
                 
sub bar {        
  print "$foo\n";
}                
}                
# Execute once
foo1234();
# Execute twice
foo1234();

OUTPUT:
foo
bar
bar
bar
[download]

This gives you '$foo will not stay shared' warnings, and the result is that '$foo' does not change after the first execution of the subroutine that Apache::Registry wraps your script in. And mod_perl executes this subroutine over and over again (that's how Apache::Registry keeps your script persistent within mod_perl).