As a one-liner

@a=map{m[(\d+)([a-z]?)-(\d+|[a-z])]and$2?(map{$1.$_}$2..$3):($1..$3)}s
+plit',',$s;
print "@a";
1 2 3 4 5 6a 6b 6c 6d 6e  10 11 12 13
[download]

Update: The above completely misses the 7!

Corrected and expanded for a little more clarity

print map{
    m[ (\d+) ([a-z]?) -? (\d+|[a-z])? ]x
    and $2
         ? ( map{ $1 . $_ } $2 .. $3 )
         : $3 ? ( $1 .. $3 )
              : ( $1 )
}split ',', $s;

1 2 3 4 5 6a 6b 6c 6d 6e 7 10 11 12 13
[download]

Slick solution, but it skips 7. Here's a fixed (and slightly more readable, using if instead of the ternary operator) version.

#!/usr/bin/perl -l

my $s = '1-5,6a-e,7,10-13';

my @a = map{ 
    if (m[ (\d+) ([a-z]?) - (\d+|[a-z]) ]x) {
      if ($2) {
        map{ $1 . $_ } $2 .. $3;
      } else {
        ( $1 .. $3 );
      }
    } else {
      $_;
    }
} split ',', $s;

print join ' ', @a;
[download]

... and the logical conclusion:

@a=map/(\d+)(\D*)-/?$2?map$1.$_,$2..$':$1.$2..$':$_,split',',$s;

A bit longer than BrowserUK's approach, but probably easier to understand and a bit more robust:

#!/usr/bin/perl

use strict;

my $list = '1-5,6a-e,7,10-13';

my @list = split(/\s*,\s*/, $list);
print join("\n", expand($_)), "\n" foreach @list;

sub expand {
    my $str = shift;
    if ($str =~ /^(\d+)\-(\d+)$/) {
        return ($1..$2);
    } elsif ($str =~ /^(\d+)([a-z]+)\-([a-z]+)$/) {
        return map {$1.$_} ($2..$3);
    } elsif ($str =~ /^\d+$/) {
        return $str;
    } else {f
        die("wrong format");
    }
}
[download]

Hope this helps, -gjb-

Quite good and very readable! Thanks.

This was a fun one. Here's a non-golfy solution I quite like, despite its assumptions.

#!/usr/bin/perl -w

use strict;
use Test::More tests => 1;

my @list = qw( 1 2 3 4 5 6a 6b 6c 6d 6e 7 10 11 12 13 );

chomp( my $range = <DATA> );

my @result = split_list( $range );
is_deeply( \@result, \@list );

sub split_list
{
    my $range  = shift;

    my @list;
    for my $r ( split( /,/, $range ) )
    {
        my $iter = get_points( $r );

        while (my $next = $iter->())
        {
            push @list, $next;
        }
    }

    return @list;
}

sub get_points
{
    my $range         = shift;
    my ($start, $end) = split( /\-/, $range );

    return iter_int($start, $end) unless $start =~ /\D/;

    my ($number, $letter) = $start =~ /^(\d+)(\D)$/;
    return iter_str( $number, $letter, $number . $end );
}

sub iter_int
{
    my ($start, $end) = @_;
    $end ||= $start;

    return sub
    {
        return if $start > $end;
        return $start++;
    };
}

sub iter_str
{
    my ($start, $letter, $end) = @_;

    my $last = '';
    return sub
    {
        return if $last eq $end;
        my $next = $start . $letter;
        $last    = $start . $letter++;
        return $next;
    };
}

__DATA__
1-5,6a-e,7,10-13
[download]

$s = '1-5,6a-e,7,10-13';
@s = split ( ',', $s );
for (@s) {
    if (/(\d+)-(\d+)/) {
      $tmp = '';
        for ( $1 .. $2 ) {
            $tmp .= "$_ ";
        }
        $_ = $tmp;
    }
}
print "@s";

# 1 2 3 4 5  6a-e 7 10 11 12 13
[download]

$s='1-5,6a-e,7,10-13';

$s =~ s/,/ /g;
$s =~ s/(\d+)-(\d+)/"{".(join ",", $1..$2)."}"/ge;
$s =~ s/([a-z]+)-([a-z]+)/"{".(join ",", $1..$2)."}"/ge;
$s =~ s/([A-Z]+)-([A-Z]+)/"{".(join ",", $1..$2)."}"/ge;

print "$_\n" for glob($s);
[download]

set_ranged_data("1-5,6a-e,7w-z,10-13");

while(my @enumerated = get_next_range()) {
    print join("\n", @enumerated);
    print "\n";
}

{
my $data;
my $pos;

sub set_ranged_data {
    $data = shift;
    $pos = 0;
    1;
}

sub get_next_range {
    return unless $data;

    my $end_pos = index($data, ",");
    $end_pos = length($data) if ($end_pos) < 0;
    my $range = substr($data, 0, $end_pos);
    substr($data, 0, $end_pos + 1) = "";
    my @enumerated = _enumerate($range);
    wantarray ? return @enumerated
              : return \@enumerated
}
sub _enumerate {
    my $range = shift;
    return ($range) unless index($range, "-") > 0;
    my ($set, $end_point) = split /-/, $range;
    my ($begin_lead, $begin_point) = _decompose($set);
    return 
        map {$begin_lead . $_} ($begin_point .. $end_point);
}

sub _decompose {
    my $set = shift;
    my ($lead, $point) = $set =~ /^(\d+)?(\D)?$/;
    return ($lead, $point) if ($lead && $point);
    return ("", $point)    if ($point);
    return ("", $lead)     if ($lead);
    return;
}

}
[download]

Thanks for the code even though there were already answers. This is what the site is all about and the many different ways of doing this helps me to expand my knowledge of the language. Thanks, Ed

use strict;
use Data::Dumper;

my $list = "1-5,6a-e,7,9-12,89xDC-G";

my @s = map { my @t = split /-/;
              my $l = length($t[0]) - 1;    # length less 1
              $#t == 0 ? $_ :
                $t[0] + 0 eq $t[0] ?        # pure number?
                  $t[0] .. $t[1] :
                  map { substr($t[0],0,$l) . $_ }
                    substr($t[0],$l,1) .. $t[1]
            } split /,/, $list;

print Dumper(\@s);
[download]

$VAR1 = [
          1,
          2,
          3,
          4,
          5,
          '6a',
          '6b',
          '6c',
          '6d',
          '6e',
          '7',
          9,
          10,
          11,
          12,
          '89xDC',
          '89xDD',
          '89xDE',
          '89xDF',
          '89xDG'
        ];
[download]

Edit: edit of course it's typo *grin*

my $list = "1-5,6a-e,7,9-12,89xFC-G";

and then

          '89xDC',
          '89xDD',
          '89xDE',
          '89xDF',
          '89xDG'

Did I miss something, or was it a typo? (89xFC changed to 89xDC)

Thanks for catching my typo! Yes I ran the code with 89xDC-G, and when I posted the code, I pasted first, and then decided to try some new data, and instead of cut and paste the modified code again, just editted by hand...

use warnings; 
use strict;

my $str = '1-5,6a-e,7,10-13';

my @ranged;
foreach ( split ',', $str ) {
  if ( /^(\d+)$/ ) {
    push @ranged, $1;
  } elsif ( /^(\d+)([a-z]+)-([a-z]+)$/ ) {
    push @ranged, map { "$1$_" } $2..$3;
  } elsif ( /^(\d+)-(\d+)$/ ) {
    push @ranged, $1..$2;
  } else {
    die "Don't know how to interpret '$_'";
  }
}

print join "\n", @ranged;
[download]