#!/usr/bin/perl -w

use strict;
my ($key);

# Collect the data
my $data = {};
while (<>)
{
    chomp;
    my @row = split /,/;
    next unless @row;
    $key = shift @row;
    # the following is the most important line in the program
    # understand it and you've got it!
    push @{$data->{$key}}, [ @row ];
}

# Uncomment these lines if you have Data::Dumper and you want to see
# what the data structure looks like
# use Data::Dumper;
# $Data::Dumper::Terse = 1;
# print Dumper($data);

print "Total count\n";
for $key (sort keys %$data)
{
    print "  $key has ", scalar @{$data->{$key}} , " entries\n";
}

print "Second and third items of all QTYs\n";

for $key (@{$data->{QTY}})
{
    print "  $key->[0], $key->[1]\n";
}

print "Third items in HDRs\n";

for $key (@{$data->{HDR}})
{
    print "  $key->[1]\n";
}

print "4th and 5th items in OTIs\n";

for $key (@{$data->{OTI}})
{
    print "  $key->[2], $key->[3]\n";
}
[download]

  perl progname.pl 824.txt

When I run it on your test data it produces this output

Total count
  AMT has 3 entries
  BGN has 1 entries
  HDR has 1 entries
  OTI has 2 entries
  QTY has 4 entries
  TED has 2 entries
Second and third items of all QTYs
  46, 10
  53, 0
  54, 10
  55, 0
Third items in HDRs
  200008081441EST
4th and 5th items in OTIs
  WEDI620000802, 159
  0021000095, 159

my %elements;
foreach (@lines) {
    my ($key, @items);
    chomp;
    ($key, @items) = split(/,/, $_);
    push @{ $elements{$key} }, [ @items ];
}
[download]

foreach my $row (@{ $elements{HRD} }) {
    print $row->[2], "\n";        # remember, offset by one
}
[download]

#!/usr/bin/perl

use warnings;
use strict;

open FILE, "input" || die "Couldn't open file";

my %hash;
              
while ( <FILE> ) {
   chomp;
   my ( $key, @rest ) = split /,/;
   foreach ( 0 .. 4 ) {
      $rest[$_] = "" unless ( defined( $rest[$_] ) );
   }
   push @{ $hash{$key} }, \@rest;
}

# To print out every 1st row of all the ones beginning with QTY
print "$_->[0]\n" foreach ( @{ $hash{QTY} } );

# total number of entries for the category
print scalar( @{ $hash{QTY} } );

# print a specific row of data
print "@{ $hash{QTY}[2] }\n";
[download]

#!/usr/local/bin/perl -w
use strict;
$|++;

use constant TITLES => 1;

my $data = {};

while ( <DATA> ) {
  my $row = [ split /,/ ];
  push @{$data->{$row->[0]}}, $row;
}

sub totals_report {
  my $data = shift;
  print "Totals Report:\n" if TITLES;
  foreach ( sort keys %{$data} ) {
    print $_ . ":\t" . @{$data->{$_}} . "\n";
  }
}

sub print_col {
  my $data = shift;
  my $col  = shift || 0;
  print 'Column ' . $col . " print out:\n" if TITLES;
  foreach my $type ( sort keys %{$data} ) {
    print $type . ":\n" if TITLES;
    foreach my $row ( @{$data->{$type}} ) {
      print "\t" . ( $row->[$col] || '[none]' ) . "\n";
    }
  }
}

totals_report( $data );

print "\n\n";

print_col( $data, 3 );

__DATA__
HDR,831 Reconciliation,200008081441EST
BGN,11,000000158,20000808,10520000
OTI,GH,BT,WEDI620000802,159
AMT,2,231644
AMT,BT,231644
AMT,NP,0
QTY,46,10
QTY,53,0
QTY,54,10
QTY,55,0
TED,ZZZ,BATCH AWAITING 831
OTI,TR,CK,0021000095,159,000101416
TED,ZZZ,MOD CHECK ON RDFI-ID FAILED
[download]

--
Casey

#!/usr/bin/perl

open (SIX,"</home/adamsj/sixtext");
@lines = <SIX>;
close(SIX);

foreach (@lines) {
    chop;
    @a_line = split(/,/);
    $key = shift @a_line;
    push(@{$all_of_it{$key}},[@a_line]);
}
foreach (keys %all_of_it) { print "$all_of_it{$_}[0][0]\n";}
[download]

foreach (@lines) {
    chop;
    ($key, $line) = split(/,/, $_, 2);
    push(@{$all_of_it{$key}},$line);
}
foreach (keys %all_of_it) { print "$key,$all_of_it{$_}[0]\n";}
[download]

print "4th item in OTIs\n";

for $key (@{$data->{OTI}})
{
    print "  $key->[3]\n";
}
[download]

You just say $data{OTI}->[0][3].

The first index number will indicate which line it is (i.e. 0 for the first OTI line, the 1 for second OTI line, etc.) while the second number indicates the element in that line. So just write: $data{type}->[line][element] to access the element you want.