Don't forget that if you don't actually make the thumbnails, and use them as clickable links to the real photos, it will causes delays as all the full size photos are downloaded just to show the thumbnails. Making thumbnails, by setting a lower size in the html code is not a good way. Thumbnails for a whole directory can be easily made:

#!/usr/bin/perl
use strict;
use Image::Magick;
my $im = Image::Magick->new;

umask 0022;

my @names = @ARGV ? @ARGV : grep { -f and -B } <*>;

for (@names) {
    if (/ /) {
        my $old = $_;
        tr, ,_,s;
        $_ .= ".jpg" unless /\.jpg$/;
        !-e and rename $old, $_ or next;
        warn "renaming $old to $_\n";
    }
    next if /\.thumb\.jpg$/;
    my $thumb = "$_.thumb.jpg";
    next if -e $thumb;
    undef @$im;
    my $ret;
    $ret = $im->Read($_)
      and warn($ret), next;
    $ret = $im->Scale( geometry => '100x100' )
      and warn($ret), next;
    $ret = $im->Write($thumb)
      and warn($ret), next;
    warn "thumbnail made for $_\n";
}
[download]