You are very close to 100% right. However I do observe something else, and I don't let things escape easily.

If I do this:

use strict;
use warnings;

{
    $_ = "1234";
    my $ret = /2/g;
    print "($ret)\n"
}
{
    $_ = "1234";
    my $ret = /9/g;
    print "($ret)\n"
}
[download]

The outputs are 1 and "empty string", which indicate that you are right.

However, try this:

use strict;
use warnings;

{
    my $a = 0;
    print "(" . ~$a . ")\n";
}
{
    my $a = 1;
    print "(" . ~$a . ")\n";
}
{
    my $a = "";
    print "(" . ~$a . ")\n";
}
[download]

It returns:

(4294967295)
(4294967294)
()
[download]

Remeber the return values for zero and empty string, and then try this:

use strict;
use warnings;

{
    $_ = "1234";
    my $ret;
    print ~ m/2/, "\n";
}
{
    $_ = "1234";
    my $ret;
    print ~ m/9/, "\n";
}
[download]

It gives you:

4294967294
4294967295
[download]

Which indicates the "~" operator does receive 0, not "empty string". Rememebr that in the case that we explicitly pass "~" an empty string, it is not converted to 0

However, if we do this:

use strict;
use warnings;

{
    $_ = "1234";
    my $ret;
    print ~ ($ret = m/2/), "\n";
    print "($ret)\n";
}
{
    $_ = "1234";
    my $ret;
    print ~ ($ret = m/9/), "\n";
    print "($ret)\n";
}
[download]

You get:

4294967294
(1)
4294967295
()
[download]

It seems that although $ret receives "empty string", "~" operator receives 0, again rememebr that we didn't see this kind of auto-convertion in the explicitly-passing-empty-string case.

!1 has a string value of "" and a numeric value of 0 (so as to not generate a warning when used as a number -- 0+"" generates a warning). This is what Perl uses all over the place for 'false' (when it isn't using undef). In the C code for Perl, this is PL_sv_no.

                - tye