#!/usr/bin/perl -w
use strict;
use Time::HiRes qw(sleep);
use Getopt::Long;
use Pod::Usage;

=head1 NAME

onchange - a little program to run a command when a file changes

=head1 SYNOPSIS

Run C<make> command whenever a source file is updated:

  $ onchange make *.c *.h &

Run C<pod2html> on a .pod file whenever it is updated:

  $ onchange 'pod2html foo.pod > foo.html' foo.pod &

Run C<make> whenever any file in the current directory, or any
directory below, is updated (ignoring files starting with .):

  $ onchange make .

=head1 OPTIONS

A couple options are available for your use:

=over

=item --verbose

See the command everytime it runs.

=item --sleep 0.1

Set the granularity of the check for file changes in seconds.
Defaults to 0.5.

=back

=cut

my $verbose = 0;
my $sleep = 0.5;
pod2usage(2) unless
  GetOptions('verbose'  => \$verbose,
             'sleep=f'  => \$sleep);

pod2usage("Too few arguements.") unless @ARGV >= 2;
my ($command, @input_files) = @ARGV;

# expand directories in @input_files list with a recursive walk and
# fill in @mtimes with mtimes for files
my (@files, @mtimes);
while (my $f = shift @input_files) {
    if (-f $f) {
        push(@files, $f);
        push(@mtimes, (stat(_))[9]);
    } elsif (-d _) {
        opendir(DIR, $f);
        push @input_files, 
          map { "$f/$_" }
            grep { $_ !~ /^\./ } readdir(DIR);
    } else {
        die "File '$f' does not exist or is not a file/directory.";
    }
}

while(1) {
    for (my $x = 0; $x < @files; $x++) {
        my $mtime = (stat($files[$x]))[9];
        next unless $mtime;
        if ($mtime != $mtimes[$x]) {
            print STDERR "Running '$command'\n" if $verbose;
            system($command);
        }
        $mtimes[$x] = $mtime;
    }
    sleep($sleep);
}