The "foreach" loop iterates over a normal list value and sets the variable VAR to be each element of the list in turn. If the variable is preceded with the keyword "my", then it is lexically scoped, and is therefore visible only within the loop. Otherwise, the variable is implicitly local to the loop and regains its former value upon exiting the loop. If the variable was previously declared with "my", it uses that variable instead of the global one, but it's still localized to the loop. This implicit localisation occurs *only* in a "foreach" loop.

Well, I had looked in the perldoc but I guess I was looking in the wrong place. Even so, I think this localization is very unDWIMy. Is there anyone out there who has been bitten by it? Is there anyway to get a warning about it? (I already tried -w and "use warnings")

Perhaps you forget that Perl is not DWIM, but DWLM (Do What Larry Means).

Luckily, Larry has given us notes about what he wants Perl to do. {grin}

Seriously, the localization is an important positive property of foreach loops, and something that while you may have just learned, has been a property of foreach loops since Perl version 1.

Asking for a warning on the locallization there would be like getting a warning on an assignment operator because "the value of the variable has now changed!". No, not gonna happen. Sometimes, you have to think for yourself, and learn what there is to learn about the language.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

Relying on the fact that the loop iterator has a defined value after leaving the loop is bad style in many languages, as many languages explicitly state the value of the loop iterator as undefined.

Personally, I prefer to create loop iterators that are scoped only to the loop block, as that completely avoids the issue:

for my $i (1..67) {
  ...
};
[download]

That way, $i can't be used outside the loop, and I consider that a good thing. But why are you using a loop over a fixed range instead of a loop from 1 to $end anyway?

perl -MHTTP::Daemon -MHTTP::Response -MLWP::Simple -e ' ;    # The  
$d = new HTTP::Daemon and fork and getprint $d->url and exit;#spider
($c = $d->accept())->get_request(); $c->send_response( new   #in the
HTTP::Response(200,$_,$_,qq(Just another Perl hacker\n))); ' #  web
[download]

#!/usr/local/bin/perl -w    #!/usr/local/bin/perl -w
use strict;                 use strict;             

my $i = 45;                 our $i = 45;

for $i (0..67) {            for $i (0..67) {
  last if $i == 10;           last if $i == 10;
  investigate();              investigate();
}                           }
print $i."\n";              print $i."\n";

sub investigate {           sub investigate {
  print "\$i=$i\n";           print "\$i=$i\n";    
}                           }
[download]

45                         0
45                         1    
45                         2    
45                         3    
45                         4    
45                         5    
45                         6    
45                         7    
45                         8    
45                         9    
$i=45                      $i=45
[download]

my $i = 45;
for (0..67) {
  my $i = $_;
  ...
}
[download]

our $i = 45;
for (0..67) {
  local $i = $_;
  ...
[download]

Can you let us know what it was you were trying to do with this code or similar?

I get the impression there's something else going on, because as presented here, the code is pretty illogical. Why make $i 45, then make it 0 two lines later?

One of the cases, when I use similar constructs is a linear search on an array, you stop, when you found an entry. You scan the entries of an array one after the other, jump out of the loop, when you found something. After the loop, you examine the index. If it is lower than the endvalue of the loop, you found something at the index:

my $i;
for ($i=0; $i<=$#list; $i++)
{
    last if found_it( $list[$i] );
}
print "Found at position $i\n"   if ($i <= $#list);
[download]

(Of course, code is simplified and not tested)

And it came to pass that in time the Great God Om spake unto Brutha, the Chosen One: "Psst!"
(Terry Pratchett, Small Gods)

why not move everything to a function and let the function return the index where the data is found?

sub search{
  my ($item,$end) = @_;
  my $i;
  my $found = 1;
  foreach $i (0..$end)
  {
      if (some condition on the list){
          return ($found, $i);
      }
  }
  return (0,0);
}
[download]

since perl supports multiple return values, we could return $found as well if someone wants it.