in reply to Writing a simple RSS aggregator.

The xml in the feed is spread over several lines, but you're reading only one at a time. No one line matches all your regex.

Try setting local $/ = '</item>'; before reading. The alternative is to forget the intermediate file, rely on the linebreaks, and do global matching a la, 

my $regex = /<title>(.*?)<\/title>\n<link>(.*?)<\/link>\n<description>
+(.*?)\n<\/description>/;  
while ($data =~ /$regex/g) {
    #...
}

[download]
That is pretty fragile, however. I suspect you're doing this as a favor and it seems odd that you have to rewrite the good xml modules to do it.

LWP::Simple is just as optional as the XML modules, which you should be able to use. There is even one for rss.

After Compline,
Zaxo

Replies are listed 'Best First'.
Re: Re: Writing a simple RSS aggregator.
by duff (Parson) on Dec 06, 2003 at 03:40 UTC

    Here are a couple of other methods that were inspired by Zaxo:

    Method #1

    #!/usr/bin/perl -w

use strict;
use LWP::Simple;
use CGI qw( :standard );
require 5.8.0;

print "Content-type: text/html\n\n";
print start_html;
my $RSS = get("http://thraxil.org/rss");

{
  local $/ = "</item>"; 
  open my $rss, "<", \$RSS or die "Aaiiigh - $!";
  while (<$rss>) {
      my ($title) = m!<title>(.*?)</title>!is;
      my ($link) = m!<link>(.*?)</link>!is;
      my ($desc) = m!<description>(.*?)</description>!is;
      next unless $title && $link && $desc;
      print "Title: $title\nLink: $link\nDescription: $desc\n\n";
  }
  close $rss;
}

    [download]

    Method #2

    #!/usr/bin/perl -w

use strict;
use LWP::Simple;
use CGI qw( :standard );

print "Content-type: text/html\n\n";
print start_html;
my $RSS = get("http://thraxil.org/rss");

my @items = $RSS =~ m!<item.*?>(.*?)</item>!gis;
for (@items) {
   my ($title) = m!<title>(.*?)</title>!is;
   my ($link) = m!<link>(.*?)</link>!is;
   my ($desc) = m!<description>(.*?)</description>!is;
   next unless $title && $link && $desc;
   print "Title: $title\nLink: $link\nDescription: $desc\n\n";
}

    [download]

    Each of these has its own merits, but if you want to do it right, use a real parser from CPAN. :-)

    PerlJam
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom