File::Find::Rule is one easy way to do what you want. glob is another and opendir/readdir is yet another.

I also suggest perlintro (if you're new to perl)

And some examples of usage

File::Find::Rule

use File::Find::Rule;

my $cnt = find(
  file     =>
  name     => "*.txt",
  maxdepth => 1,
  in       => "/home/a"
);
[download]

glob - Update: fixed bug as noted by sauoq below (it was originally going to be @{ [ glob "*.txt" ] }, that'll teach me for posting in a hurry :)

my $cnt = () = glob "/home/a/*.txt";
[download]

opendir, readdir + grep

opendir( my $d, "/home/a" ) or die "ack: $!";
my $cnt = grep { -f and /\.txt$/ } readdir $d;
[download]

HTH

_________
broquaint

my $cnt = glob "/home/a/*.txt";

Unfortunately, no. It would be more intuitive that way, but the real behavior of that is to set $cnt to the first filename in the list of exansions.

$ touch {a,b,c}.txt; perl -le 'my $c = glob "*.txt"; print $c'
a.txt
[download]

The clunky fix is to force list context...

$ touch {a,b,c}.txt; perl -le 'my $c =()= glob "*.txt"; print $c'
3
[download]

-sauoq
"My two cents aren't worth a dime.";

Since you seem to work on a Un*x system you could also simply resort to command line tools that are quite up to this task. (That is, if you're only after the result of what you ask about.)

  find /home/a -type f -name "*.txt" | wc -l
[download]

  find /home/a -type f -name "*.txt" -maxdepth 0 | wc -l
[download]

The /home/a is the directory you want to search, -type f specifies that you're only interested in files, -name "*.txt" implies that you only want files that have a .txt suffix, -maxdepth 0 specifies that you want 0 levels of recursion, i.e. you want find to limit itself to the directory specified.

Learning how to use find definitely pays off, see the relevant man page for more info since it is really very powerful, especially when using the -exec flag.

Hope this helps, -gjb-

Easier method for one directory is ofcourse


  ls /home/a/*.txt |wc -l
[download]

But learning find is definedly worth it as well :).

UPDATE:
Duh, was *.txt. Double duh, ls goes wild if dir name matches as well, so be careful. Find tends to be easier to keep under control :P.

to avoid ls wildness and to get a true listing of all files ( some versions of ls, like hp-ux, put multiple files on one line ) do ls -ald /home/a/*.txt | wc -l And Find is also your Friend.

-maxdepth is not implemented on all versions of find. beware. a suitable replacement for getting the number of *.txt files in the current directory is  ls | egrep '\.txt$' |wc -l with the caveat that directory names that end in .txt will be falsely listed in the count.


-Waswas

This would miss hidden files. Maybe ls -lad *.txt | grep -v ^d | wc -l would be a better solution.

/dev/null

perl -le 'print scalar @{[</home/a/*.txt>]}'

Welcome to the forum!

Watch out for dirctories ending in .txt

$ touch temp.txt

$ mkdir dir.txt

$ perl -le 'print scalar @{[<./*.txt>]}'
2
[download]

Try this:

$ perl -le 'print scalar @{[grep {-f} <./*.txt>]}'
1
[download]

--

flounder

opendir(DIR, '/home/a') or die "couldn't opendir /home/a: $!";
while (local $_ = readdir(DIR)) {
        next unless $_ =~ /\.txt$/;
        print "$_\n";
}
closedir(DIR) or die "couldn't close /home/a: $!";
[download]

I'd have written that as

opendir(DIR, "/home/a") || die "can't open dir: $!";
my $count = grep(/\.txt$/, readdir(DIR));
closedir(DIR);
print "There are $count .txt files\n";
[download]

assuming that the only purpose is to get a count of matching files.

Michael

That has the disadvantage of potentially using a lot of memory if there are many files in the directory (the globbing solutions, and solutions that use readdir in list context all suffer from this).

I would use something like:

    my $cnt = 0;
    local $_;
    chdir "/home/a" or die "chdir: $!";
    opendir my $dh => "." or die "opendir: $!";
    -f && /\.txt$/ && $cnt ++ while defined ($_ = readdir $dh);
    closedir $dh;
[download]

Abigail

#!/usr/bin/perl -w
use strict;

my $total;
for ( glob ('/home/a/*.txt') ) {
    $total++ if ! -d;
}
print "The total is $total\n";
[download]

Cheers - L~R

use strict;
use warnings;
use Data::Dumper;

my @txt_files = map {m!(.*\.txt)[^/]*$!} split /\n/, `ls -F`;
                    #   ^txt only  ^want non-directories
                    #               and throw away the flag

print Dumper(\@txt_files);

my $num_files = $#txt_files + 1;
[download]

Not very elegant, but:

$filecount = 0;
@filesindir = `ls /home/a/*.txt`;
foreach $file (@filesindir) {
    $filecount++;
}

print "The number of text files in my directory is: $filecount\n";
[download]