grep can help. It actually helps you in both replace and search (before you do insert). Read perlfunc for details.

use warnings;
use strict;

my @a = ("a=1", "b=2", "c=3");
for my $e (grep /^b=/, @a) {
    $e = "b=22";
}
print join(",", @a);
[download]

The other way is to use hash, as you are handling key-value pairs.

Update:

See my reply to devgoddess's reply. I made a general purpose sub there.

Hmmm... You mean I should put the array into a hash? That just sounds like it's a lot more complicated than it needs to be. I simply need to check the @lines array created with Tie::File for those entries and, if they're not present, add them to the end of the array... hence, the end of the file.

Can you explain a little more what you mean about using a hash?

Dev Goddess
Developer / Analyst / Criminal Mastermind

"Size doesn't matter. It's all about speed and performance."

It is fine to stay with array. Hope the following code helps:

Made a general purpose function to handle both replace and insert, and determines whether to insert or replace on its own:

use warnings;
use strict;

my @a = ("a=1", "b=2", "c=3");
print join(",", @a), "\n";
add("b", 22);#this replaces
print join(",", @a), "\n";
add("d", 45);#this inserts
print join(",", @a), "\n";

sub add {
    my ($key, $val) = @_;
    my $exists = 0;
    for (grep /^$key=/, @a) {
        $_ = "$key=$val";
        $exists = 1;    
    } 
    if (!$exists) {
        push @a, "$key=$val"
    }
}
[download]

Not for the low level problem of inserting lines in a file, but for the general purpose of managing a configuration file, you might also consider using a dedicated module.

A quick search on CPAN leads for example on those ones :

• Parse::PlainConfig, which allows to read an write simple config files;
• ConfigReader::Simple, which may parse several configuration files (for example /etc/config /usr/local/etc/config $HOME/.config);
• Parse::PerlConfig, which uses config files written in Perl.

Parse::PlainConfig may be the most interesting in this case, as it allows both to write the configuration file and to store lists (were they of servers or of something else) and even hashes.

Another solution, taking back the idea of a simple key=value file, using a hash, but directly reading from and writing to file, without using File::Tie neither another existing module.

---

# SimplestConfig.pm

# SimplestConfig->new('filename') returns an object whose attributes
# (simple values only at this time) will be stored in a file named
# filename under the form attribute=value and as such may be usefull
# to manage simple config files.

use strict;
use warnings;

package SimplestConfig;

sub new {
    my ($class, $filename) = @_;
    my $self = {_FileName_ => $filename};
    bless $self, $class;
    if (open CFG, "<$filename") {
        while (<CFG>) {
            /^\s*(\S.*?)\s*=\s*(.*?)\s*$/ and $self->{$1} = $2;
        }
        close CFG;
    } else {
        warn "Can't read $filename, creating it\n";
    }
    return $self;
}

sub DESTROY {
    my ($self) = @_;
    open CFG, ">$self->{_FileName_}" or
        die "Can't write $self->{_FileName_}\n";
    delete $self->{_FileName_};
    print CFG map "$_=$self->{$_}\n", sort keys(%{$self});
    close CFG;
}

1;
[download]

---

#!/usr/bin/perl -w
# test1.pl

use strict;

use lib "$ENV{HOME}/perl";
use SimplestConfig;

my $cfg = SimplestConfig->new("$ENV{HOME}/test.cfg");
$cfg->{a} = 1;
$cfg->{b} = 2;
$cfg->{c} = 3;
[download]

---

#!/usr/bin/perl -w
# test2.pl

use strict;

use lib "$ENV{HOME}/perl";
use SimplestConfig;

my $cfg = SimplestConfig->new("$ENV{HOME}/test.cfg");
$cfg->{b} = 20;
$cfg->{d} = 4;
[download]

---

Test:

$ more test.cfg
test.cfg: No such file or directory
$ ./test1.pl
Can't read /home/laurent/test.cfg, creating it
$ more test.cfg
a=1
b=2
c=3
$ ./test2.pl
$ more test.cfg
a=1
b=20
c=3
d=4
[download]

Note it would discard any line not of the form key=value from an existing file.

And on another subject, Happy New Year to everybody.

Again, thank you all so much for the code and the tips. I'm still working on the code (not actively, or it would have been done by now, but I was ill the last few days), and I'd like to do a write-up on it when it's done, if you guys think the code's good enough. ;) I'll post it when I've got it all tweaked.

Oh, one more thing... Any idea why I get a syntax error using Tie::File for the line

tie @lines, 'Tie::File', filename or die ...;

When I take off "or die ...;" it works fine. Of course, this isn't desirable. If it can't find the file, I want it to give an error message and die.

Later. :)

Could you copy and paste thet actual line of code? Because currently, it looks just peachy.


Who is Kayser Söze?
Code is (almost) always untested.

Sure thing.

tie @lines, 'Tie::File', $hostsfile or die ...;

Dev Goddess
Developer / Analyst / Criminal Mastermind

"Size doesn't matter. It's all about speed and performance."