#!/usr/bin/perl

use strict;
use warnings;

$" = ", ";

while (<DATA>) {
    /^(\w+)(?:[(](\d+)[)])?:?/g or next;
    my ($status, $exit) = ($1, $2);
    my (@vars)          = /\G[^(]*[(]([^)]*)[)]/g;
    print "Status: $status; ";
    print "Exit: $exit; "     if defined $exit;
    print "Variables [@vars]" if @vars;
    print "\n";
}

__DATA__
OFF
SUCCESS: (abc)
ERROR(1): disk number (27) crashed at (11:03)
WARNING(1): system is rebooting



Status: OFF; 
Status: SUCCESS; Variables [abc]
Status: ERROR; Exit: 1; Variables [27, 11:03]
Status: WARNING; Exit: 1;
[download]

Abigail

Your data lines are different enough that each type needs its own parser. A hash of coderefs ("dispatch table") will do that nicely,

my $parser = {
    OFF => sub {()},
    SUCCESS => sub {
        local $_ = shift;
        /\((\w*)\)/
    },  # call these in list context!
    ERROR1 => sub {
        local $_ = shift;
        /disk number \((\d+)\) at \((\d+:\d+)\)/;
    },
    WARNING1 => sub {
        local $_ = shift;
        /(\w.*)^/;
    }
};

sub parse_line {
    local $_ = shift;
    my ($key, $data) = split ':', $_, 2;
    $key =~ tr/()//d;
    ($key, $parser->{$key}->($data));
}
[download]

Your data lines are different enough that each type needs its own parser.

Uhm, no, as shown in several other replies.

A hash of coderefs ("dispatch table") will do that nicely,

Actually, your solution is very inflexible. It can't even deal with:

WARNING(2): system is rebooting
[download]

(only the exit value is different from the original). It'll produce an error, as Perl will try to use an undefined value as a code reference.

Abigail

Hard to do robustly with a regex

while(<DATA>) {
    chomp;
    my ( @bits, $rest );
    ( $bits[0], $rest ) = split ':', $_, 2;
    $bits[0] =~ tr/()//d;
    push @bits, ($rest =~ m!\(([^)]+)!g) if $rest;
    print "@bits\n";
}

__DATA__
OFF
SUCCESS: (abc)
ERROR(1): disk number (27) crashed at (11:03)
WARNING(1): system is rebooting
[download]

Which gives you

OFF
SUCCESS abc
ERROR1 27 11:03
WARNING1
[download]

Don't you just wish that repeat counts would repeat enclosed captures? Then you could use

m[
    ( ^ [^(:]+ )
    (?:
        (?: \( ( \d+ ) \) )?
        :
        (?: .*? \( ( [^)]+ ) \) ){1,}
        .*
    )?
    $
]x;
[download]

to grab repetative elements instead of having to do (or rather not do) things with built in limits, like this.

#! perl -slw
use strict;

while( <DATA> ) {
    chomp;
    my @bits = grep{ defined }
        m[
            ( ^ [^(:]+ )
            (?:
                (?: \( ( \d+ ) \) )?
                :
                (?:
                    .*?
                    \( ( [^)]+ ) \)
                    (?:
                        .*?
                        \( ( [^)]+ ) \)
                        (?:
                            .*?
                            \( ( [^)]+ ) \)
                            (?:
                                .*?
                                \( ( [^)]+ ) \)
                            )?
                        )?
                    )?
                )?
                .*
            )?
            $
        ]x;
    print join'/', @bits;
}

=Output
P:\test>junk
OFF
SUCCESS/abc
ERROR/1/27/11:03
WARNING/1
TEST/255/this/that/the other/and this
=cut

__DATA__
OFF
SUCCESS: (abc)
ERROR(1): disk number (27) crashed at (11:03)
WARNING(1): system is rebooting
TEST(255): (this) (that) (the other) (and this) (but not this)
[download]

---

Examine what is said, not who speaks.

"Efficiency is intelligent laziness." -David Dunham
"Think for yourself!" - Abigail
Hooray!

my $tempstr = $str;
# get rid of () around status
$tempstr =~ s/^([^(:]+)\(([^)]+)\)/$1$2/;
# grab the status and anything in parentheses
@needed = $tempstr =~ /(^[^:]+|(?<=\()[^)]+(?=\)))/g;
[download]

Update: or do it the other way around:

@needed = $_ =~ /(^[^:]+|(?<=\()[^)]+(?=\)))/g;
$needed[0] =~ y/()//d;
[download]

# this is the original string
$string=""; 
# then split on first ':'
($begin,$end)=split (/:/,$string,2); 
# remember every () separately
# this assumes that between () there are no more (), eg not (27(b))
while ($end=~m/\((.+?)\)/g) { 
  push (@result,$1); 
}
# add first
unshift (@result,$b);
# if wanted to remove () from first
# check if need to escape
$result[0]=~s/[()]/;
[download]

My solution is in the same realm.

my($begin, $end) = split /:/, $string, 2;
$begin =~ tr/()//d;
@result = $begin;
push @result, $end =~ m/\((.+?)\)/g;
[download]