use File::Find;
finddepth sub {
  my $old = $_;
  return unless -f and s/\.abc$/.def/;
  warn("won't overwrite existing file at $File::Find::name"), return
    if -e;
  rename $old, $_ or warn "Cannot rename $old to $_ in $File::Find::di
+r: $!";
}, ".";
[download]

-- Randal L. Schwartz, Perl hacker

for ( glob "*.abc" ) {
  ($new = $_) =~ s/\.abc$/.edf/; 
   rename $_, $new or warn "can't rename '$_' to '$new': !";
}
[download]

Note 1: On Unix at least, rename will never delete a file. But renaming a file to a clear screen string can be almost as bad.

Note 2: The camel3 p 154 explains better than I could the idiom ($a = $b) =~ s///

Use this with caution. rename will destroy any file that gets in its way. Also, you don't need that =~ in front of the s///:

for ( glob "*.abc" ) 
{
   my $old = $_;
   s/\.abc$/.edf/; 
   rename $old, $_ or warn "can't rename '$old' to '$_'";
}
[download]

Update:
Ok, I looked again at stefp's code and I see why that =~ was there. If you use that method, don't forget to declare $new somewhere... (you are using strict, aren't you?) and of course, you might want to add some code to make sure rename isn't going to delete anything. maybe:

for( glob "*.abc" )
{
    my $new = $_;
    my $ok = 1;
    substr $new, 0, -3, "edf";
    if( -e $new )
    {
        warn "file '$new' already exists. Do you want to replace?\n";
        while(<STDIN>)
        {
            last if /[yY][eEsS]{0,1}/;
            $ok = 0, last if /[nN][oO]{0,1}/;
            warn "Yes or No?\r";
        }
    }
    
    rename $_, $new or warn "can't rename '$_' to '$new'\n " if $ok;
}
[download]

That is untested...

 
#!/usr/bin/perl -w

use strict;
use File::Find;

my $dir = '.'; # or wherever

find(\&myrename, $dir);

sub myrename {
    my $file1 = $_;
    my $file2 = $_;
    if ($file2 =~ s/\.abc$/.edf/) {
        print "renamed  $file1, $file2\n" if rename $file1, $file2;
    }
}
[download]

I hope there are no directories named "*.abc". Here's another way:

#!/usr/bin/perl -w

use strict;
use File::Find;

my $dir = '.'; # or wherever

find(\&myrename, $dir);

sub myrename {
    return unless -f and /(.*?)\.abc$/s;
    my $new_name = $1.".edf";
    if (rename $_, $new_name) {
        print "renamed  $File::Find::name to $new_name\n";
    } else {
        warn "Couldn't rename $File::Find::name to $new_name: $!";
    }
}
[download]

for ( glob "*.abc" ) {
  ($new = $_) =~ s/\.abc$/.edf/; 
   rename $_, $new or warn "can't rename '$old' to '$new'";
}
[download]

Oh, I see what you're doing now. I kind of glanced at it and said, "but why would he bind $_ to a pattern match?"... he he, because you aren't.

By the way, you can edit your old posts to add updates and the like (or to fix mistakes like your $old) by going to the node itself.