A regex is best suited to altering the array in place s/(\w)(\w*)/\U$1\E$2/ for @array; You can use a regex, but to make a new array with initial caps, ucfirst is handier, my @arrayl = map {ucfirst} @array; The regex can also be applied to a string with the /g flag

$_ = 'foo bar foobar barfoo 1 2 3';
s/(\w)(\w*)/\U$1\E$2/g;
print;
# Foo Bar Foobar Barfoo 1 2 3
[download]

An easier regex/substitution would be:

my @array = qw/one Two three four five/;
s/(.)/\u\L$1/ for @array;
[download]

If the latter,

my @array1 = map ucfirst, @array;
[download]

If you hit the Library, under Perl Functions, Alphabetical, you'll find ucfirst() and lcfirst(), which will upper- or lower-case (respectively) the first character of a given word. So you could do something along the lines of:

my @array = qw( foo bar foobar barfoo 1 2 3 );

foreach my $i (0 .. $#array) {
    $array[$i] = ucfirst($array[$i]);
}
[download]

I suspect a regex in this case is actually overkill.... HTH....

Or even faster:

foreach (@array) { ucfirst($_); }
[download]

In this case, $_ will point to the actual element in the array.

Unfortunately, that doesn't work

my @words = qw[ the quick brown fox ];

foreach (@words) { ucfirst($_); };
Useless use of ucfirst in void context at ...
[download]

It would have to be

foreach (@words) { $_ = ucfirst($_); }
[download]

Or, more simple

$_ = ucfirst for @words;

print for @words;
The
Quick
Brown
Fox
[download]

---

Examine what is said, not who speaks.

"Efficiency is intelligent laziness." -David Dunham
"Think for yourself!" - Abigail
Timing (and a little luck) are everything!

The exercise to parse through your array would be another issue.

update: Don't know where my mind was but I forgot about ucfirst. Thanx ysth.

my @array = qw(foo bar foobar barfoo 1 2 3);
my @caps = map "\u$_", @array;
print "@caps\n";
[download]