-- Randal L. Schwartz, Perl hacker

if(!open DAT, "ads.dat") {
    print "Error: cannot open data file!\n";
    exit 1;
} else {

    @imgdata=<DAT>;
    foreach $c (@imgdata) {
        ($id,$image,$url,$type)=split(/\|/,$c);

        if ($type=~/^(internal|partner)$/) {
            push (@imgs, $image);
        }
    }

    $img  = $imgs[int(rand($#imgs+1))];
    print "Location: $img\n\n";
}
[download]

kilinrax: nice code, but we can get rid of your foreach loop:

open DAT, "ads.dat" or die "Error: cannot open data file: $!\n";

@imgdata=<DAT>;
@imgs = grep { s/^[^|]+\|([^|]+)\|[^|]+\|(?:internal|partner)$/$1/ } @
+imgdata;

$img  = $imgs[int(rand($#imgs+1))];
print "Location: $img\n\n";
[download]

Cheers,
Ovid

I noticed everyone else had better, shorter answers than mine, sniff, sniff, so I just HAD to do something. Here's the regex broken out, for those who have asked for it:

s/^            # Beginning of string
   [^|]+       # Everything up to the next bar
   \|          # The bar
   (           # Capture to $1
     [^|]+     # Everything up to the next bar
   )           # End capture
   \|          # The bar
   [^|]+       # Everything up to the next bar
   \|          # The bar
   (?:         # Non-capturing parens
     internal  # the string "internal"
     |         # or
     partner   # the string "partner"
   )$          # End of string
   /$1/x       # Substitute $1 for string
[download]

Join the Perlmonks Setiathome Group or just go the the link and check out our stats.

hi kilinrax, u'r suggestion is the most effective, thanks allot.... oh btw. the image does rotates fine, but how will i be able to save the correct URL ($url) for the correct image? i will be saving the correct url to the cookie. the script should be able to rotate the image with corresponding url. thanks again.

Here's some code that will do the same job (hopefully):

    open DAT, "ads.dat" or die "Can't open data file: $!";
    my @valid =
        grep $_->[3] =~ /^internal|partner$/,
        map [ split /\|/ ], <DAT>;
    close DAT or die "Can't close data file: $!";

    my $which = $valid[ rand @valid ];
    print "Location: ", $which->[2], "\n\n";
[download]

hi btrott, i think the code u've just suggested does not prints any images. thanks again.

#!usr/local/bin/perl
use strict;
$|++;

my ($c, $id, $image, $url, $type, @imgs, $img);

open DAT, "ads.dat" or die "Error: cannot open data file!\n";
my @imgdata=<DAT>;
close DAT;

$id  = int(rand(scalar @imgdata));

$c = @imgdata[$id];
{
    chop $c;
    ($id,$image,$url,$type)=split(/\|/,$c);
}
print "Location: $type\n\n";
[download]

#!/usr/bin/perl -w
use strict;
use LWP::Simple;

use vars qw($in_file @imgdata @imgs 
            $num     $id      $image 
            $url     $type    $format
            $out_file);
$in_file = 'ads.dat';

@imgdata = <DATA>;

@imgs = grep {/\|(?:internal|partner)$/} @imgdata;

$num = int(rand($#imgs) +1);

($id, $image, $url, $type) = split /\|/, $imgs[$num];

$url = $url . $image;
$format = $1 if $image =~ /\.(\w+)$/;
$format = 'jpeg' if $format =~ /^jpe?g$/;

$out_file  = get($url);
print "Content-type: image/$format\n\n";
print $out_file;

__DATA__
1|/images/dibona_sm.gif|http://perlmonks.org|internal
2|/images/usermonkpics/ovidmonk.gif|http://perlmonks.org|partner
3|/pics/gol.gif|http://www.f.com|payed
[download]

<img src="http://www.somedomain.com/cgi-bin/myscriptname.cgi" alt="Ran
+dom image">
[download]

Cheers,
Ovid

Join the Perlmonks Setiathome Group or just go the the link and check out our stats.

Thanks for this example, ovid.

I had a little better luck with a version of this script I reworked the parens in the random image chooser like this:

my $num = int(rand($#imgs +1));

I had a list of just two images, and I kept getting the same image routine. I didn't think too hard about why my change worked any better, though. :)

-mark