while($info = $sth->fetchrow_hashref) {
    @case = keys %{ $info };
    print @case; 
}
[download]

Your DBI stuff is fine. Your problem is your reference syntax. Try this:

while($info = $sth->fetchrow_hashref) {
  for (keys %$info) {
     print "$_ => $$info{$_}\n";
  }
}
[download]

You can also use %{$info} instead of %$info, but IMO that syntax is noisier and usually unnecessary. (Sometimes you have to use it, for example when you are interpolating and the variable is directly followed by word characters that would otherwise be taken for part of the variable name.)

The syntax you use, %{info}, is exactly the same as saying %info -- that is to say, it doesn't dereference $info, but refers to a completely separate variable instead, a hash variable called %info. You want either %{$info} or %$info.

You may also occasionally see an arrow syntax, like $info->{key} = $value, but for now you don't need to worry about that. Just know that when you do see it, it's a dereferencing syntax.

The reason for the %{info} syntax is so that 'info' can be replaced with an arbitrary expression. For example, under no strict refs you could say %{"in" . "fo"} and it would still refer to %{info}. It does not however refer to the same thing as %{$info}.

The first is that References quick reference may help clear up some confusion about how to use references. The second is that using strict.pm would have caught the fact that you were using them incorrectly and have assisted in debugging.

It would make the code cleaner and easier (I thought) if I fetched a hash instead of an array (like usual).

SNIP

What I'm trying to end up having happen is my CGI script will have popup menus. I was wanting those popup menu's populated with entries from the SQL query. To make this easier I thought I would fetch a hash, dump all of the values from the hash into an array and use that array to in the popup menu.

fetchrow_hashref is best when you're selecting a number of things out from the database and you don't want to have to care what order you're doing that in. For example:

select name, address, phonehome, phonework from addressbook;
[download]

Considering that you've said that you just want to dump all the values from the hash into an array I get the distinct impression that you're SQL is more like:

select name from addressbook;
[download]

$info = {
             name => "fred",
};
[download]

You can achieve what you want with the following:

my @case;
while( my $info = $sth->fetchrow_hashref) {
      push @case, $info->{name};
}
print "@case\n";      # prints built up @case.
[download]

I think what you're looking for is selectcol_arrayref. This selects all the (appropriate values) from a single column and returns an array ref to them. So this:

my $names = $dbh->selectcol_arrayref(
               "select name from addressbook where name like ?",
               undef,
               $name 
) or die "select failed. " . $dbh->errstr;

my @case = @$names;   # If you'd rather deal with an array
print "@case\n";      # prints out ALL of the names selected.
[download]

I hope this helps

jarich

It answers alot of common errors.

Also search perlmonks for DBI and "placeholders".

I don't see any prepare statements to go along with your $sth lines. Like:

$sth = $dbh->prepare("SELECT * FROM table" );
[download]

Aside from the specific problem in your code, what you want to achieve an also be done with:

my @case = @{$sth->{NAME}};
while(my $info = $sth->fetchrow_hashref) {
    for (@case) {
        print "$_ => $info->{$_}\n";
    }
}
[download]

I recommend reading DBI Recipes, which deals with several issues related to fetching hashrefs from a database.

BTW, the probable reason for your mistake is that you are not using strict.

"What I'm trying to end up having happen is my CGI script will have popup menus. I was wanting those popup menu's populated with entries from the SQL query. To make this easier I thought I would fetch a hash, dump all of the values from the hash into an array and use that array to in the popup menu."

This, of course, all depends upon what your database table and query results look like. I will assume the following table:

states
+--------+------------------+----+
| Field  | Type             | PK |
+--------+------------------+----+
| id     | int(10) unsigned |  y |
| name   | varchar(64)      |    |
| abbrev | char(2)          |    |
+--------+------------------+----+

use DBI;
use HTML::Template;
use CGI qw(:standard);

my $dbh = DBI->connect(
    qw(DBI:vendor:database:host user pass),
    {RaiseError=>1},
);

my $states = $dbh->selectall_arrayref('
   select id,name from state order by name
',{Slice => {}});

my $tmpl = HTML::Template->new(filehandle => \*DATA);
$tmpl->param(states => $states);

print header,$tmpl->output;

__DATA__
<form>
<select name="states">
<tmpl_loop states>
   <option value="<tmpl_var id>"><tmpl_var name></option>
</tmpl_loop>
</select>
<p><input type="submit" /></p>
</form>
[download]

$_->{id} == param('state') and $_->{sel} = 1 for @$states;
[download]

<option value="<tmpl_var id>" <tmpl_if sel>selected="1"</tmpl_if>>
   <tmpl_var name>
</option>
[download]

... beginning same as before ...
my $states = $dbh->selectall_arrayref( ... );
my $tmpl   = HTML::Template->new(filehandle => \*DATA);

$tmpl->param(states =>
   scrolling_list(
      -name     => 'states',
      -values   => [ map $_->{id}, @$states ],
      -size     => 12,
      -multiple => 'why not',
      -labels   => { map {$_->{id} => $_->{name}} @$states },
   ),
);

print header,$tmpl->output;

__DATA__
<form>
<tmpl_var states>
<p><input type="submit" /></p>
</form>
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)