Update: You might want to read perldoc -q duplicate for a general discussion of using a hash to check for duplicates.

I know giving a complete solution is sometimes frowned upon here, but sometimes I just can't help myself. Here is the first script:

    #!/usr/bin/perl
    use strict;
    use warnings;

    my %nets;
    /^Net '([^']+)'/ 
        and not $nets{$1}++ 
        and print "$1\n" 
      while <STDIN>;
[download]

And the second:

    #!/usr/bin/perl
    use strict;
    use warnings;
    use File::Slurp;

    my $file2 = shift
        or die "Usage: $0 file2 < another-file";
    my $nets = join "|", map {chomp;$_} read_file($file2);

    /$nets/
        or print
      while <STDIN>;
[download]

And you can run the whole chain with something like:

    perl script1.pl < file1 > file2
    perl script2.pl file2 < another-file
[download]

Update: just for fun, here's a version that will do everything in one step:

    #!/usr/bin/perl
    use strict;
    use warnings;
    use File::Slurp;

    my $file1 = shift
        or die "Usage: $0 file1 < another-file";
    my $nets = join "|", map { chomp;
                               /^Net '([^']+)'/ and $1 or ()
                             } read_file($file1);

    /$nets/
        or print
      while <STDIN>;
[download]

Which would be used like:

    perl script1+2.pl file1 < another-file
[download]

Thanks for your help. One problem tho, my system HPUX does not support "FILE::SLURP", it there another approach to this step? Your first part did work great, can't wait to start PERL class! My shell scripts were taking minutes to do the things that PERL got done in mere seconds. Thanks again! RCP

another approach to this step?

Of course! :-)

The idiomatic slurp goes something like this:

    my $data = do { local (@ARGV, $/) = $filename; <> };
[download]

You may see why I chose to use File::Slurp originally. To integrate that into the second snippet, it would be:

    #!/usr/bin/perl
    use strict;
    use warnings;

    my $file = shift
        or die "Usage: $0 file2 < another-file";
    my $file_contents = do { local (@ARGV, $/) = $file; <> };
    my $nets = join "|", map {chomp;$_} $file_contents;

    /$nets/
        or print
      while <STDIN>;
[download]

Note: this code is untested.

Update: please note that some people get upset when you write "PERL." The language is called Perl, and the program that executes Perl code is called perl. Perl is not an acronym, so capitalizing its name makes it look like you're shouting.

I'm finding it hard to visualize what you are trying to do. Can you modify your original post so that it's more obvious?

To figure out which thing is in one file but not another, put the conents of each file into separate hashes, and using the keys from the first hash, check the second hash. It's pretty standard Perl Cookbook (as published by O'Reilly's) stuff.

I have a file "file1" that contains: dave bob rich jim I have a second file "file2" that contains: dave rich I need "file2" listing to remove lines from "file1" to create a "file3" that contains only: bob jim I tried this code: #!/usr/bin/perl use strict; # use warnings; open(MYOUTFILE, ">file3"); open(MYOUTFILE, ">>file3"); my $file = shift or die "Usage: $0 file1 < file2"; my $file_contents = do { local (@ARGV, $/) = $file; <> }; my $nets = join "|", map {chomp;$_} $file_contents; /$nets/ or print MYOUTFILE while <STDIN>; close(MYOUTFILE); But it does not get me my example of file3 should look like. Help! Thanks.. RCP

From the Perl debugger session I just ran:

[alex@rand alex]$ perl -de 1

Loading DB routines from perl5db.pl version 1.19
Editor support available.

Enter h or `h h' for help, or `man perldebug' for more help.

main::(-e:1):   1
  DB<1> @file1=qw/dave bob rich jim/;

  DB<2> @file2=qw/dave rich/;

  DB<3> foreach(@file1){$list{$_}=1;}

  DB<4> foreach(@file2){delete $list{$_};}

  DB<5> print "Remaining elements " . join("; ",keys %list) . "\n";
Remaining elements jim; bob

  DB<6>
[download]

You can fiddle with the 'list' hash as you read the file, so there's no need to use an array as the middle man.

Alex / talexb / Toronto

Life is short: get busy!

PS: When posting code, put it in between 'code' tags. That way it doesn't wrap like normal text.

my %hash=();
while(<>) {
  if (/Net '(\w+)'/){$hash{$1} = 1;}
}
print "$_\n" for keys %hash;
[download]