For this to work, you need new to return an object. Right now it just returns undef.

Firstly, you need to read perlsub to learn how subs work, and the important difference between $_ and @_.

Then turn to perlootut to learn the basics of object-oriented programming in Perl.

Here's how you could write your code...

use strict;
use warnings;

{
    package testor;
    
    sub new {
        my $class = shift;
        return bless {
            component_name => $_[0],
        }, $class;
    }
    
    sub component_name {
        my $self = shift;
        return $self->{component_name};
    }
    
    sub isExist {
        my $self = shift;
        return 0;
    }
}

my $myComponent = '7-Zip 9.20 (x64 edition)';
my $checker = testor->new($myComponent);

if( $checker->isExist ) {
    print $checker->component_name, " already installed\n";
}
else {
    print $checker->component_name, " not installed\n";
}

[download]

But personally I'd write it as...

use strict;
use warnings;

{
    package testor;
    use Moo;
    
    has component_name => ( is => 'ro' );
    
    sub isExist {
        my $self = shift;
        return 0;
    }
}

my $myComponent = '7-Zip 9.20 (x64 edition)';
my $checker = testor->new(component_name => $myComponent);

if( $checker->isExist ) {
    print $checker->component_name, " already installed\n";
}
else {
    print $checker->component_name, " not installed\n";
}

[download]

Either way, read those bits of Perl documentation I mentioned, and learn why your original attempt is wrong.

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

In reply to Re: newbie's question on inheritance by tobyink
in thread newbie's question on inheritance by anaconda_wly

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.