my $self = shift not only defines $self; it also modifies @_ (removing the first array item). The difference is only significant if you intend on using @_ or goto later on in the sub.

Update: Personally I've recently decided to adopt a coding style where I use shift for the invocant (i.e. $self or $class; but also "conceptual invocants" like $orig in Moose around method modifiers, or $ctx in Catalyst actions) and list assignment for other parameters.

For example:

use v5.14;

package Person {
  use Moose;
  has first_name => (is => 'rw', isa => 'Str');
  has last_name  => (is => 'rw', isa => 'Str');

  sub set_name {
    my $self = shift;
    my ($first, $last) = @_;
    $self->first_name($first);
    $self->last_name($last);
  }
}

package LoudNameChanges {
  use Moose::Role;
  around set_name => sub {
    my $orig = shift;
    my $self = shift;
    say "Changing name to: @_";
    $self->$orig(@_);
  };
}

package Person::LoudNameChanges {
  use Moose;
  extends 'Person'; with 'LoudNameChanges';
}

my $bob = Person::LoudNameChanges->new(
  first_name => 'Robert',
  last_name  => 'Smith',
);

$bob->set_name('David', 'Jones');

print $bob->dump;

[download]

For regular subs which are not intended to be called as methods, there is no invocant, so I just use list assignment to unpack all the arguments.

Why did I decide to adopt this style? I find it works nicely in terms of delegating method calls and so forth where you often need to pass on @_ to other methods and functions, but without passing on the invocant.

I'm not yet very strict with myself about this style, but hopefully it will become habit soon.

package Cow { use Moo; has name => (is => 'lazy', default => sub { 'Mooington' }) } say Cow->new->name

In reply to Re: Difference between my $self = shift and my ($self) = @_ by tobyink
in thread Difference between my $self = shift and my ($self) = @_ by Doctrin

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.