Sadly File::ReadBackwards doesn't provide the ability to specify encodings or PerlIO layers. It just reads the file as bytes. (File a bug report!)

That doesn't mean your task is impossible - you just need to manually encode/decode in a few places.

use 5.008;
use strict;
use warnings;

use Encode qw( encode decode );
use File::Temp qw( tempfile );
use File::ReadBackwards qw();

# Pick a random filename
(undef, my $filename) = tempfile();

# Create some content for an example
{
    open my $fh, ">:encoding(UTF-32LE)", $filename
        or die "can haz file?? $!";
    print $fh "$_\n" for qw/ foo bar baz /;
    close $fh;
}

# Now let's open it. Note that we need to tell File::ReadBackwards
# that the line seperator is the UTF-32-encoded version of "\n".
my $fh = "File::ReadBackwards"->new(
    $filename,
    encode("UTF-32LE", "\n") => 0,
) or die "can haz file?? $!";

# Read each line
while (defined(my $line = $fh->readline))
{
    # Need to decode line from UTF-32 to Perl's internal encoding
    $line = decode("UTF-32LE", $line);
    
    print "GOT: $line";
}

# Delete our temp file
unlink $filename;

[download]
package Cow { use Moo; has name => (is => 'lazy', default => sub { 'Mooington' }) } say Cow->new->name

In reply to Re: How do I use the "File::ReadBackwards" and open in "Unicode text, UTF-32, little-endian" mode by tobyink
in thread How do I use the "File::ReadBackwards" and open in "Unicode text, UTF-32, little-endian" mode by hashperl

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.