Hello, I tried to implement McA's idea: 

use strict;
use warnings;
use File::Find;
use 5.010;

# Use current dir of no dir is supplied
@ARGV = qw(.) unless @ARGV;

my @inaccessible;

# Leave out inaccesible top dirs
@ARGV = grep {
    if ( -d $_ and !-r _ ) {
        push @inaccessible, $_;
        0;    # don't pass on inaccessible dir
    } else {
        1;
    }
} @ARGV;

# Do we have some dirs we can chdir to?
unless (@ARGV) {
    print_report();
    exit;
}

find( { wanted => \&process, preprocess => \&preprocess }, @ARGV );

print_report();

sub process {

    # do something;
}

sub preprocess {
    grep {
        if ( -d $_ and !-r _ ) {
            push @inaccessible, "$File::Find::dir/$_";
            0;    # don't pass on inaccessible dir
        } else {
            1;
        }
    } @_;
}

sub print_report {
    say "I couldn't chdir to these directories:";
    say "\t$_" for @inaccessible;
}

[download]

We are what we repeatedly do. Excellence, then, is not an act but a habit. -- Will Durant (Aristotle)

In reply to Re: File::Find and permission error handling by reisinge
in thread File::Find and permission error handling by budik_je_vypnuty

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.