#! perl
use strict;
use warnings;
use Scalar::Util qw(looks_like_number);
use Text::CSV;

my %accounts;
read_accounts ('a.csv');
merge_balances('b.csv');

print "\nOverdue accounts:\n\n";
my $count = 0;

for (keys %accounts)
{
    if ($accounts{$_}{overdue})
    {
        print 'Number:  ', $_,                      "\n";
        print 'Name:    ', $accounts{$_}{name},     "\n";
        print 'Created: ', $accounts{$_}{cdate},    "\n";
        print 'Balance: ', $accounts{$_}{balance},  "\n";
        print 'Due:     ', $accounts{$_}{due_date}, "\n\n";
        ++$count;
    }
}

print "Total overdue accounts: $count\n";

sub read_accounts
{
    my $file = shift;
    my $csv  = Text::CSV->new({ binary => 1 })
        or die 'Cannot use CSV: ' . Text::CSV->error_diag();
 
    open(my $fh, '<', $file)
        or die "Cannot open file '$file' for reading: $!";

    $csv->getline($fh);     # Discard first line (headings)

    while (my $row = $csv->getline($fh))
    {
        my ($number, $name, $created) = @$row[1 .. 3];

        die "Found duplicate accounts numbered '$number'"
            if exists $accounts{$number};

        $accounts{$number} = { cdate => $created,
                               name  => $name };
    }

    close $fh or die "Cannot close file '$file': $!";
    $csv->eof or $csv->error_diag();
}

sub merge_balances
{
    my $file = shift;
    my $csv  = Text::CSV->new({ binary => 1 })
        or die 'Cannot use CSV: ' . Text::CSV->error_diag();
 
    open(my $fh, '<', $file)
        or die "Cannot open file '$file' for reading: $!";

    $csv->getline($fh);     # Discard first line (headings)

    while (my $row = $csv->getline($fh))
    {
        my ($due_date, $balance, $number) = @$row[1 .. 3];

        $balance = 0 unless looks_like_number($balance);

        if (exists $accounts{$number})
        {
            $accounts{$number}{balance}  = $balance;
            $accounts{$number}{due_date} = $due_date;
            $accounts{$number}{overdue}  =
                $balance > 0 && is_overdue($due_date, 10, 23, 2007);
        }
        else
        {
            warn "Account '$number' not found\n";
        }
    }

    close $fh or die "Cannot close file '$file': $!";
    $csv->eof or $csv->error_diag();
}

sub is_overdue
{
    my ($date, $cutoff_month, $cutoff_day, $cutoff_year) = @_;

    my ($month, $day, $year) =
        $date =~ m! ^ (\d{1,2}) / (\d{1,2}) / (\d{4}) !x;

    return 1 if $year  < $cutoff_year;
    return 0 if $year  > $cutoff_year;
    return 1 if $month < $cutoff_month;
    return 0 if $month > $cutoff_month;
    return 1 if $day   < $cutoff_day;
    return 0;
}
[download]