Here's a possible solution for what—I think—you're trying to achieve:

#! /usr/bin/env perl
use 5.014; use warnings;

# We're going to try matching substrings of this...
my $MASTER_STR = 'abcdabcdabceabcdabcdabceab';

# Using this pattern to find (possibly truncated) repetitions...
my $REPETITION_PAT = qr{

    \A         # Start at the beginning of the string
    (.+?)      # Match minimal initial sequence (as $1)
    (?{$^N})   # Remember it internally (as $^R)

    (?|        # Then either it's not truncated...
        \1+        # Rematch it exactly as often as possible
        \z         # ...until the end of the string
        ()         # Remember that nothing was left over (as $2)

    |          # Or else it is truncated...
        \1*        # Rematch it exactly as often as possible (or not)
        (.+)       # Then grab what's left (as $2)(internally as $^N)
        \z         # ...until the end of the string

        # Then verify that what's left is a proper truncation...
        (??{
            # If what's left ($^N) is substring of repetition ($^R)...
            $^N eq substr($^R,0,length($^N))
                ? q{}       # ...then do nothing (i.e. keep matching)
                : q{(?!)}   # ...else initiate backtracking
        })
    )
}xms;

# Loop through increasingly truncated substrings...
for my $substr (1..length($MASTER_STR)) {

    # Compute the substring...
    my $str = substr($MASTER_STR,0,-$substr);

    # Evaluate the match...
    if ($str =~ $REPETITION_PAT) {
        say "$str\n     Matched: $1*$2";
    }
    else {
        say "$str\n     Didn't match";
    }
}
[download]

Damian

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.