G'day symgryph,

Here's my take on a solution:

#!/usr/bin/env perl

use 5.010;
use strict;
use warnings;

local ($/, $") = ("", ',');
my @fields = qw{user summary access group};
my $re = qr{ (?: ^user:\s(?<user>\S+)
             |   ^\s*summary\s"(?<summary>[^"]+)
             |   ^\s*access-level\s(?<access>\S+)
             |   ^\s*group\s(?<group>\S+) ) }mx;

while (<DATA>) {
    my %data;
    @data{keys %+} = values %+ while m{$re}g;
    say "@{[ map { $_ // '' } @data{@fields} ]}";
}   

__DATA__
user: myus44 [up] 
------------
 admin-state enabled 
 summary "Johnny Cash" 
 access-level group-defined 
 group mi-group  [up]

user: jar1543 [up] 
------------
 admin-state enabled 
 summary "Lara Croft" 
 access-level group-defined 
 group jar-head  [up]

user: myprivilegeduser [up]
-----------
admin-state enabled
access-level privileged

[download]

Output:

$ pm_1047505_regex.pl
myus44,Johnny Cash,group-defined,mi-group
jar1543,Lara Croft,group-defined,jar-head
myprivilegeduser,,privileged,

[download]

While this produces the output you indicated, you may want to revisit your requirements. ++Tux makes some very good points in this regard.

-- Ken

In reply to Re: Multi Line Matching- getting into csv by kcott
in thread Multi Line Matching- getting into csv by symgryph

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.