What's wrong with your code:

• You never read your input file, you just open it. There should either be a readline somewhere or a <FH>
• The =~ operator binds the variable on its left to the expression on its right. So in my $line =~ /$key/ you try to find $key in a brand new variable with nothing in it (that's what my does). Obviously you don't find it. Just below that, you have a lonely (/\S+\s($key).*/; there's no =~ so you do that on the default variable : $_ . Since you never wrote in it, that's probably not what you meant.
• Your first $1 contains the same thing as $key, since that's what you were looking for in the first place.
• It's probably better to work the other way around: loop through the file once and for each paragraph search through all the keys. Or, search for a key in paragraph and check that it exists
• There's a way to read a file paragraph by paragraph, you just have to set $/ to "". But what you did you still work

From all of that:

use strict;  
use warnings;    
use Data::Dumper;

my %result = (key1 => undef, key2 => undef, key3 => undef);
{       # So that the effect of local is limited to that block
        local $/ = 'ENDKEY';
        while( my $line = <DATA>) # <FH> in your case
        {
                next unless $line =~ m<HIT \s+ (key\d+)\b >x;
                my $key = $1;
                next unless exists $result{$key};
                $result{$key} = { attrib1 => 'null', attribmsg => 'nul
+l' };
                while ($line =~ m<\s+ (attrib1 | attribmsg) :.*? = \s+
+ (\w+) >gx)
                {
                        $result{$key}{$1} = $2;
                }
        }
}

print Dumper \%result;

__DATA__
HIT key1 so start to process
    attrib1:  base = FULL
        attribmsg: middle = MEDIUM
ENDKEY

HIT key2 so start to process
    attrib1:  base = FULL
ENDKEY

HIT key9 so start to process
    attrib1:  base = FULL
ENDKEY
[download]

$VAR1 = {
          'key2' => {
                      'attribmsg' => 'null',
                      'attrib1' => 'FULL'
                    },
          'key1' => {
                      'attribmsg' => 'MEDIUM',
                      'attrib1' => 'FULL'
                    },
          'key3' => undef
        };
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.