I agree with the other monks, there’s nothing wrong with using map. However, it is possible to get an equivalent result without map by rearranging and adding the /g and /m modifiers to the regex:

my @online_services = `svcs` =~ /^online.*svc:(.*?):/gm;

[download]

Note that this works because the binding operator puts its left-hand operand into scalar context; and backticks (or qx//) in scalar context return “a single (potentially multi-line) string” (Quote Like Operators).

My benckmark tests suggest that this approach may also be more efficient:

#! perl
use strict;
use warnings;
use Benchmark    'cmpthese';
use Data::Dump;
use experimental 'smartmatch';

my (@x, @y);

cmpthese
(
    100,
    {
        MAP   => sub { @x =  map     { /\d+_(\S*?)\.pl$/ } `ls -l` },
        G_MOD => sub { @y = `ls -l` =~ /\d+_(\S*?)\.pl$/gm         },
    }
);

if (@x ~~ @y)
{
    printf "The arrays are equal; each has %d elements\n", scalar @x;
}
else
{
    print "The arrays are different:";
    dd \@x;
    print "----------\n";
    dd \@y;
}

[download]

Typical output:

13:56 >perl 720_SoPW.pl
        Rate   MAP G_MOD
MAP   47.1/s    --  -32%
G_MOD 68.9/s   46%    --
The arrays are equal; each has 619 elements

13:59 >

[download]

Note: Although I’m on Windows, I ended up using Cygwin’s ls -l command because `dir \n` gives an error, and `dir` causes the comparison test to crash. I don’t know what’s going on there. :-(

But by all means stick with map if you’re more comfortable with it.

Hope that helps,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

In reply to Re: Capturing regex from map by Athanasius
in thread Capturing regex from map by trippledubs

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.