The note is interesting: they are highlighting this difference between ECMA script REs and Perl REs.

The RE (x+)? is very similar to (x*), except that the latter will always match (and, therefore, never have the value from a previous match if it is in an enclosing repeating group. This is similar to the requirement in Note 3: "Step 4 of the RepeatMatcher clears Atom's captures each time Atom is repeated." Because it always matches it always has a value from the last repeat of the outer repeating group, as if it was reset for each repeat, except that the value is '' instead of undef in the case that x did not match. This is an easy transformation.

I appreciate that you don't want to change the RE but you say you are parsing it, so perhaps you can make some systematic transformations.

Consider:

use strict;
use warnings;
use Data::Dumper::Concise;
 
my $string = "aacbbbcac";
 
my $re = '((a+)?(b+)?(c))*';

# transform '(x+)?' to '(x*)' assuming 'x' is monolithic
$re =~ s/\Q+)?/*)/g;
print "re = $re\n";

my $re1 = qr/$re/;


if ($string =~ $re1) {
  my @something;
  foreach (0..$#-) {
    if(defined($-[$_])) {
        my $substring = substr($string, $-[$_], $+[$_] - $-[$_]);

        # ${$_} also works, except where $_ = 0
        no strict 'refs';
        print "\$substring = $substring = ${$_}\n";

        # transform '' to undef
        $substring = undef if($substring eq '');

        # assert: $substring is now as specified by
        # Standard ECMA-262, 5.1 Edition / June 2011
        # Section 15.10.2.5 Note 3

        printf "Group %d: <%s>\n", $_, $substring // '';
        $something[$_] = $substring;
    }
  }

  print Dumper(\@something);
}

[download]

Produces

re = ((a*)(b*)(c))*
$substring = aacbbbcac = test.pl
Group 0: <aacbbbcac>
$substring = ac = ac
Group 1: <ac>
$substring = a = a
Group 2: <a>
$substring =  =
Group 3: <>
$substring = c = c
Group 4: <c>
[
  "aacbbbcac",
  "ac",
  "a",
  undef,
  "c"
]

[download]

In reply to Re^7: Explain a regexp matched group result by ig
in thread Explain a regexp matched group result by jdd

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.