Generally speaking I'm in favour of splitting as much logic as possible out into object-oriented modules.

#!/usr/bin/env perl

use strict;
use warnings;

# This could go into a separate ".pm" file.
{
    package DirectoryProcessor;
    
    use Class::Tiny { 
        script  => sub { $ENV{DIR_PROCESSOR_SCRIPT} || "echo -e" },
        verbose => sub { 0 },
    };
    use Getopt::Long qw( GetOptionsFromArray );
    
    sub process {
        my $self = shift;
        my ($dir) = @_;
        
        my $cmd = sprintf('%s %s', $self->script, $dir);
        chomp( my $ret = `$cmd` );
        print qq(Output: "$ret"\n) if $self->verbose;
    }
    
    sub process_all {
        my $self = shift;
        $self->process($_) for @_;
    }
    
    sub handle_argv
    {
        my $class = shift;
        my ($argv, $opt) = @_;
        
        $argv ||= \@ARGV;
        $opt  ||= {};
        
        GetOptionsFromArray($argv, $opt, 'script=s', 'verbose!');
        
        my $self = $class->new($opt);
        $self->process_all(@$argv);
    }    
}

# Here's the body of the script.
DirectoryProcessor->handle_argv;

[download]
use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name

In reply to Re: Best Practice: How do I pass option parameters to functions? by tobyink
in thread Best Practice: How do I pass option parameters to functions? by An_Idea_Within

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.