G'day ccelt09,

Here's my take on a solution. I've output to a hash (with possibly unneeded, additional data): easily modified for printing. I've kept the interval data unchanged. I've made slight changes to the line data: most lines match multiple ranges; some match none. 

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dumper;
use Inline::Files;

my (@range, %capture);
my $line_re = qr[^(?:\d+\s+){3}(\d+)];

while (<INTERVALS>) {
    my ($min, $max) = (split)[1,2];
    push @range => [ $min, $max ];
    $capture{range}{$min} = $max;
}

while (<FRAME>) {
    chomp;
    collate($_);
}

{
    local $Data::Dumper::Indent = 1;
    local $Data::Dumper::Sortkeys = 1;
    print Dumper \%capture;
}

sub collate {
    my $line = shift;
    my ($key) = $line =~ $line_re;

    for (@range) {
        last if $_->[0] > $key;
        next if $_->[1] < $key;
        push @{$capture{data}{$_->[0]}} => $line;
    }
}

__INTERVALS__
chrX    1   1000001
chrX    100001  1100001
chrX    200001  1200001
chrX    300001  1300001
chrX    400001  1400001
chrX    500001  1500001
chrX    600001  1600001
chrX    700001  1700001
chrX    800001  1800001
__FRAME__
0 25 27 260692 2 2 3 2 2 3 3 3 2 3 1 1 2 1 2 2 3 3 2 1 2 1 1 1 2 3
0 19 33 160466 2 2 3 2 2 2 3 3 3 3 1 1 2 1 2 3 3 3 2 1 2 3 2 2 3 3
0 25 27 60454 2 2 3 2 2 3 3 3 2 3 1 1 2 1 2 2 3 3 2 1 2 1 1 1 2 3
0 25 27 3260882 2 2 3 2 2 3 3 3 2 3 1 1 2 1 2 2 3 3 2 1 2 1 1 1 2 3
0 50 2 460727 1 1 1 1 1 2 1 1 2 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1
0 48 4 860814 1 1 1 1 1 1 2 1 1 3 1 1 1 1 1 1 2 1 1 1 1 1 1 1 1 1
0 46 6 1660866 1 1 1 1 1 1 1 3 1 1 1 1 1 1 1 2 2 2 1 1 1 1 1 1 1 2
0 48 4 6460888 1 1 1 1 1 1 1 2 1 1 1 1 1 1 1 2 2 1 1 1 1 1 1 1 1 2
0 50 2 60909 1 1 1 1 1 2 1 1 2 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1

[download]

Output:

<Reveal this spoiler or all in this thread>

-- Ken

In reply to Re: Sorting Data By Overlapping Intervals by kcott
in thread Sorting Data By Overlapping Intervals by ccelt09

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.