The following expresses my understanding of your situation, based upon your original posting:

If my understanding is correct, the following--which uses a hash of arrays (HoA)--provides one solution:

use strict;
use warnings;

my ( @header, %hash );
my @files = qw/File1.txt File2.txt/;
local $, = "\n";

for my $file (@files) {
    open my $fhIN, '<', $file or die $!;

    while ( my $line = <$fhIN> ) {
        my @columns = split ' ', $line;

        if ( $. == 1 ) {
            @header = @columns;
        }
        else {
            push @{ $hash{ $header[$_] } }, $columns[$_] for 1 .. $#co
+lumns;
        }
    }

    close $fhIN;

    for my $i ( 1 .. $#header ) {
        open my $fhOUT, '>', "$file\_$header[$i].txt" or die $!;
        print $fhOUT @{ $hash{ $header[$i] } };
        close $fhOUT;
    }

    undef %hash;
}

[download]

Each file in @files is processed. If it's the first line of the file ($. contains the current line number), then it's the header line, and is saved.

For lines 2 .. n, you'll note the following:

 push @{ $hash{ $header[$_] } }, $columns[$_] for 1 .. $#columns;
      ^            ^                 ^            ^    ^
      |            |                 |            |    |
      |            |                 |            |    + - To the last
+ index
      |            |                 |            + - Starting at the 
+next index after the index for ID
      |            |                 + - Column value
      |            + - Column heading
      + - Generate a HoA, where: keys are column names; values are ref
+erences to lists of column entries

[download]

The for my $i ( 1 .. $#header ) { ... iterates through all of the column headers, except the ID, using them as keys to access the array of column values.

A file is created for each column. The naming scheme is the file's name plus the column's name. (If you didn't want files created, it's within this for loop that you can operate on the columns' values.)

You may have noticed the earlier local $, = "\n"; notation. This will cause a newline to be placed between the array's elements when printed, so each element will be on its own line. To use a different format, just set the value of $, to something else, e.g., "," or "\t".

Potential issues:

Hope this helps!

In reply to Re: How to add column into array from delimited tab file by Kenosis
in thread How to add column into array from delimited tab file by hellohello1

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.